sys-devel/autoconf/autoconf-2.69-r5.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 if [[ ${PV} == "9999" ]] ; then
   7         EGIT_REPO_URI="https://git.savannah.gnu.org/git/autoconf.git"
   8         inherit git-r3
   9 else
  10         SRC_URI="mirror://gnu/${PN}/${P}.tar.xz
  11                 ftp://alpha.gnu.org/pub/gnu/${PN}/${P}.tar.xz
  12                 https://dev.gentoo.org/~polynomial-c/dist/${P}-runstatedir_patches.tar.xz"
  13         KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  14 fi
  15
  16 inherit toolchain-autoconf
  17
  18 DESCRIPTION="Used to create autoconfiguration files"
  19 HOMEPAGE="https://www.gnu.org/software/autoconf/autoconf.html"
  20
  21 LICENSE="GPL-3"
  22 SLOT="${PV}"
  23 IUSE="emacs"
  24
  25 BDEPEND=">=sys-devel/m4-1.4.16
  26         >=dev-lang/perl-5.6"
  27 RDEPEND="${BDEPEND}
  28         !~sys-devel/${P}:2.5
  29         >=sys-devel/autoconf-wrapper-13"
  30 [[ ${PV} == "9999" ]] && BDEPEND+=" >=sys-apps/texinfo-4.3"
  31 PDEPEND="emacs? ( app-emacs/autoconf-mode )"
  32
  33 PATCHES=(
  34         "${FILESDIR}"/${PN}-2.69-perl-5.26.patch
  35         "${FILESDIR}"/${P}-fix-libtool-test.patch
  36         "${FILESDIR}"/${PN}-2.69-perl-5.26-2.patch
  37
  38         "${WORKDIR}"/patches/${P}-runstatedir.patch
  39         "${WORKDIR}"/patches/${P}-texinfo.patch
  40         "${WORKDIR}"/patches/${P}-runstatedir_info.patch
  41 )
  42
  43 src_prepare() {
  44         # usr/bin/libtool is provided by binutils-apple, need gnu libtool
  45         if [[ ${CHOST} == *-darwin* ]] ; then
  46                 PATCHES+=( "${FILESDIR}"/${PN}-2.61-darwin.patch )
  47         fi
  48
  49         # Save timestamp to avoid later makeinfo call
  50         touch -r doc/{,old_}autoconf.texi || die
  51
  52         toolchain-autoconf_src_prepare
  53
  54         # Restore timestamp to avoid makeinfo call
  55         # We already have an up to date autoconf.info page at this point.
  56         touch -r doc/{old_,}autoconf.texi || die
  57 }