sys-devel/autoconf/autoconf-2.13-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit toolchain-autoconf
   7
   8 DESCRIPTION="Used to create autoconfiguration files"
   9 HOMEPAGE="https://www.gnu.org/software/autoconf/autoconf.html"
  10 SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="${PV:0:3}"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv s390 sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  15 IUSE="userland_BSD"
  16
  17 DEPEND=">=sys-apps/texinfo-4.3
  18         =sys-devel/m4-1.4*
  19         dev-lang/perl"
  20 RDEPEND="${DEPEND}
  21         >=sys-devel/autoconf-wrapper-13"
  22
  23 PATCHES=(
  24         "${FILESDIR}"/${P}-gentoo.patch
  25         "${FILESDIR}"/${P}-destdir.patch
  26         "${FILESDIR}"/${P}-test-fixes.patch #146592
  27         "${FILESDIR}"/${PN}-2.13-perl-5.26.patch
  28 )
  29
  30 src_configure() {
  31         # make sure configure is newer than configure.in
  32         touch configure || die
  33
  34         # need to include --exec-prefix and --bindir or our
  35         # DESTDIR patch will trigger sandbox hate :(
  36         #
  37         # need to force locale to C to avoid bugs in the old
  38         # configure script breaking the install paths #351982
  39         #
  40         # force to `awk` so that we don't encode another awk that
  41         # happens to currently be installed, but might later be
  42         # uninstalled (like mawk).  same for m4.
  43         local prepend=""
  44         use userland_BSD && prepend="g"
  45         ac_cv_path_M4="${prepend}m4" \
  46         ac_cv_prog_AWK="${prepend}awk" \
  47         LC_ALL=C \
  48         econf \
  49                 --exec-prefix="${EPREFIX}"/usr \
  50                 --bindir="${EPREFIX}"/usr/bin \
  51                 --program-suffix="-${PV}"
  52 }