sys-cluster/kube-apiserver/kube-apiserver-1.8.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit user golang-build golang-vcs-snapshot
   6
   7 EGO_PN="k8s.io/kubernetes"
   8 ARCHIVE_URI="https://github.com/kubernetes/kubernetes/archive/v${PV}.tar.gz -> kubernetes-${PV}.tar.gz"
   9 KEYWORDS="~amd64"
  10
  11 DESCRIPTION="Kubernetes API server"
  12 HOMEPAGE="https://github.com/kubernetes/kubernetes https://kubernetes.io"
  13 SRC_URI="${ARCHIVE_URI}"
  14
  15 LICENSE="Apache-2.0"
  16 SLOT="0"
  17
  18 DEPEND="dev-go/go-bindata"
  19
  20 RESTRICT="test"
  21
  22 pkg_setup() {
  23         enewgroup ${PN}
  24         enewuser ${PN} -1 -1 -1 ${PN}
  25 }
  26
  27 src_prepare() {
  28         default
  29         sed -i -e "/vendor\/github.com\/jteeuwen\/go-bindata\/go-bindata/d" src/${EGO_PN}/hack/lib/golang.sh || die
  30         sed -i -e "/export PATH/d" src/${EGO_PN}/hack/generate-bindata.sh || die
  31 }
  32
  33 src_compile() {
  34         LDFLAGS="" GOPATH="${WORKDIR}/${P}" emake -j1 -C src/${EGO_PN} WHAT=cmd/${PN}
  35 }
  36
  37 src_install() {
  38         pushd src/${EGO_PN} || die
  39         dobin _output/bin/${PN}
  40         popd || die
  41         keepdir /var/log/${PN}
  42         fowners ${PN}:${PN} /var/log/${PN}
  43         newinitd "${FILESDIR}"/${PN}.initd ${PN}
  44         newconfd "${FILESDIR}"/${PN}.confd ${PN}
  45         insinto /etc/logrotate.d
  46         newins "${FILESDIR}"/${PN}.logrotated ${PN}
  47 }