sys-cluster/kube-apiserver/kube-apiserver-1.17.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit go-module
   6
   7 DESCRIPTION="Kubernetes API server"
   8 HOMEPAGE="https://github.com/kubernetes/kubernetes https://kubernetes.io"
   9 SRC_URI="https://github.com/kubernetes/kubernetes/archive/v${PV}.tar.gz -> kubernetes-${PV}.tar.gz"
  10
  11 LICENSE="Apache-2.0"
  12 SLOT="0"
  13 KEYWORDS="~amd64"
  14
  15 COMMON_DEPEND="acct-group/kube-apiserver
  16         acct-user/kube-apiserver"
  17 DEPEND="${COMMON_DEPEND}
  18         dev-go/go-bindata
  19         >=dev-lang/go-1.13"
  20 RDEPEND="${COMMON_DEPEND}"
  21
  22 RESTRICT="test"
  23 S="${WORKDIR}/kubernetes-${PV}"
  24
  25 src_prepare() {
  26         default
  27         sed -i -e "/vendor\/github.com\/jteeuwen\/go-bindata\/go-bindata/d" -e "s/-s -w/-w/" hack/lib/golang.sh || die
  28         sed -i -e "/export PATH/d" hack/generate-bindata.sh || die
  29 }
  30
  31 src_compile() {
  32         LDFLAGS="" emake -j1 WHAT=cmd/${PN} GOFLAGS=-v
  33 }
  34
  35 src_install() {
  36         dobin _output/bin/${PN}
  37         keepdir /var/log/${PN}
  38         fowners ${PN}:${PN} /var/log/${PN}
  39         newinitd "${FILESDIR}"/${PN}.initd ${PN}
  40         newconfd "${FILESDIR}"/${PN}.confd ${PN}
  41         insinto /etc/logrotate.d
  42         newins "${FILESDIR}"/${PN}.logrotated ${PN}
  43 }