sys-cluster/ceph/ceph-14.2.8-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python3_{6,7} )
   6 CMAKE_MAKEFILE_GENERATOR=emake
   7
   8 DISTUTILS_OPTIONAL=1
   9
  10 inherit check-reqs bash-completion-r1 cmake-utils distutils-r1 flag-o-matic \
  11                 multiprocessing python-r1 udev readme.gentoo-r1 toolchain-funcs \
  12                 systemd
  13
  14 if [[ ${PV} == *9999* ]]; then
  15         inherit git-r3
  16         EGIT_REPO_URI="https://github.com/ceph/ceph.git"
  17         SRC_URI=""
  18 else
  19         SRC_URI="https://download.ceph.com/tarballs/${P}.tar.gz"
  20         KEYWORDS="~amd64 ~ppc64"
  21 fi
  22
  23 DESCRIPTION="Ceph distributed filesystem"
  24 HOMEPAGE="https://ceph.com/"
  25
  26 LICENSE="LGPL-2.1 CC-BY-SA-3.0 GPL-2 GPL-2+ LGPL-2+ BSD Boost-1.0 MIT public-domain"
  27 SLOT="0"
  28
  29 CPU_FLAGS_X86=(sse{,2,3,4_1,4_2} ssse3)
  30
  31 IUSE="babeltrace +cephfs custom-cflags dpdk fuse grafana jemalloc kerberos ldap"
  32 IUSE+=" libressl lttng +mgr numa rabbitmq +radosgw +ssl spdk "
  33 IUSE+=" system-boost systemd +tcmalloc test xfs zfs"
  34 IUSE+=" $(printf "cpu_flags_x86_%s\n" ${CPU_FLAGS_X86[@]})"
  35
  36 COMMON_DEPEND="
  37         acct-group/ceph
  38         acct-user/ceph
  39         virtual/libudev:=
  40         app-arch/bzip2:=
  41         app-arch/lz4:=
  42         app-arch/snappy:=
  43         app-arch/zstd:=
  44         app-shells/bash:0
  45         app-misc/jq:=
  46         dev-libs/crypto++:=
  47         dev-libs/leveldb:=[snappy,tcmalloc(-)?]
  48         dev-libs/libaio:=
  49         dev-libs/libnl:3=
  50         dev-libs/libxml2:=
  51         dev-libs/nss:=
  52         sys-auth/oath-toolkit:=
  53         sys-apps/coreutils
  54         sys-apps/grep
  55         sys-apps/keyutils:=
  56         sys-apps/util-linux:=
  57         sys-apps/sed
  58         sys-apps/util-linux
  59         sys-libs/libcap-ng:=
  60         sys-libs/ncurses:0=
  61         sys-libs/zlib:=
  62         babeltrace? ( dev-util/babeltrace )
  63         ldap? ( net-nds/openldap:= )
  64         lttng? ( dev-util/lttng-ust:= )
  65         fuse? ( sys-fs/fuse:0= )
  66         kerberos? ( virtual/krb5 )
  67         rabbitmq? ( net-libs/rabbitmq-c:= )
  68         ssl? (
  69                 !libressl? ( dev-libs/openssl:= )
  70                 libressl? ( dev-libs/libressl:= )
  71         )
  72         xfs? ( sys-fs/xfsprogs:= )
  73         zfs? ( sys-fs/zfs:= )
  74         radosgw? (
  75                 dev-libs/expat:=
  76                 !libressl? (
  77                         dev-libs/openssl:=
  78                         net-misc/curl:=[curl_ssl_openssl]
  79                 )
  80                 libressl? (
  81                         dev-libs/libressl:=
  82                         net-misc/curl:=[curl_ssl_libressl]
  83                 )
  84         )
  85         system-boost? ( =dev-libs/boost-1.72*[threads,context,python,${PYTHON_USEDEP}] )
  86         jemalloc? ( dev-libs/jemalloc:= )
  87         !jemalloc? ( >=dev-util/google-perftools-2.6.1:= )
  88         ${PYTHON_DEPS}
  89 "
  90 BDEPEND="
  91         amd64? ( dev-lang/yasm )
  92         x86? ( dev-lang/yasm )
  93         app-arch/cpio
  94         >=dev-util/cmake-3.5.0
  95         dev-python/cython[${PYTHON_USEDEP}]
  96         dev-python/sphinx
  97         dev-util/cunit
  98         dev-util/gperf
  99         dev-util/valgrind
 100         sys-apps/coreutils
 101         sys-apps/findutils
 102         sys-apps/grep
 103         sys-apps/sed
 104         sys-apps/which
 105         sys-devel/bc
 106         sys-devel/patch
 107         virtual/pkgconfig
 108         test? (
 109                 dev-python/coverage[${PYTHON_USEDEP}]
 110                 dev-python/virtualenv[${PYTHON_USEDEP}]
 111                 dev-python/requests-mock[${PYTHON_USEDEP}]
 112                 sys-apps/grep[pcre]
 113                 sys-fs/btrfs-progs
 114         )
 115 "
 116 RDEPEND="${COMMON_DEPEND}
 117         net-misc/socat
 118         sys-apps/gptfdisk
 119         sys-block/parted
 120         sys-fs/cryptsetup
 121         sys-fs/lvm2[-device-mapper-only(-)]
 122         sys-fs/lsscsi
 123         virtual/awk
 124         dev-python/bcrypt[${PYTHON_USEDEP}]
 125         dev-python/cherrypy[${PYTHON_USEDEP}]
 126         dev-python/flask[${PYTHON_USEDEP}]
 127         dev-python/jinja[${PYTHON_USEDEP}]
 128         dev-python/pecan[${PYTHON_USEDEP}]
 129         dev-python/prettytable[${PYTHON_USEDEP}]
 130         dev-python/pyopenssl[${PYTHON_USEDEP}]
 131         dev-python/requests[${PYTHON_USEDEP}]
 132         dev-python/werkzeug[${PYTHON_USEDEP}]
 133         mgr? (
 134                 dev-python/more-itertools[${PYTHON_USEDEP}]
 135                 dev-python/pyjwt[${PYTHON_USEDEP}]
 136                 dev-python/pyyaml[${PYTHON_USEDEP}]
 137                 dev-python/routes[${PYTHON_USEDEP}]
 138                 dev-python/six[${PYTHON_USEDEP}]
 139         )
 140 "
 141 REQUIRED_USE="
 142         ${PYTHON_REQUIRED_USE}
 143         mgr? ( cephfs )
 144         ?? ( jemalloc tcmalloc )
 145         rabbitmq? ( radosgw )
 146 "
 147
 148 # the tests need root access
 149 RESTRICT="test? ( userpriv )"
 150
 151 # distribution tarball does not include everything needed for tests
 152 RESTRICT+=" test"
 153
 154 # false positives unless all USE flags are on
 155 CMAKE_WARN_UNUSED_CLI="no"
 156
 157 PATCHES=(
 158         "${FILESDIR}/ceph-12.2.0-use-provided-cpu-flag-values.patch"
 159         "${FILESDIR}/ceph-14.2.0-cflags.patch"
 160         "${FILESDIR}/ceph-12.2.4-boost-build-none-options.patch"
 161         "${FILESDIR}/ceph-13.2.0-cflags.patch"
 162         "${FILESDIR}/ceph-14.2.0-mgr-python-version.patch"
 163         "${FILESDIR}/ceph-14.2.5-no-virtualenvs.patch"
 164         "${FILESDIR}/ceph-13.2.2-dont-install-sysvinit-script.patch"
 165         "${FILESDIR}/ceph-14.2.0-dpdk-cflags.patch"
 166         "${FILESDIR}/ceph-14.2.0-link-crc32-statically.patch"
 167         "${FILESDIR}/ceph-14.2.0-cython-0.29.patch"
 168         "${FILESDIR}/ceph-14.2.3-dpdk-compile-fix-1.patch"
 169         "${FILESDIR}/ceph-14.2.4-python-executable.patch"
 170         "${FILESDIR}/ceph-14.2.4-undefined-behaviour.patch"
 171 )
 172
 173 check-reqs_export_vars() {
 174         if use amd64; then
 175                 CHECKREQS_DISK_BUILD="12G"
 176                 CHECKREQS_DISK_USR="460M"
 177         else
 178                 CHECKREQS_DISK_BUILD="1400M"
 179                 CHECKREQS_DISK_USR="450M"
 180         fi
 181
 182         export CHECKREQS_DISK_BUILD CHECKREQS_DISK_USR
 183 }
 184
 185 pkg_pretend() {
 186         check-reqs_export_vars
 187         check-reqs_pkg_pretend
 188 }
 189
 190 pkg_setup() {
 191         python_setup 'python3*'
 192         check-reqs_export_vars
 193         check-reqs_pkg_setup
 194 }
 195
 196 src_prepare() {
 197         cmake-utils_src_prepare
 198
 199         if use system-boost; then
 200                 eapply "${FILESDIR}/ceph-14.2.8-boost-sonames.patch"
 201
 202                 find "${S}" -name '*.cmake' -or -name 'CMakeLists.txt' -print0 \
 203                         | xargs --null sed \
 204                         -e 's|Boost::|Boost_|g' \
 205                         -e 's|Boost_boost|boost_system|g' -i || die
 206         fi
 207
 208         sed -i -r "s:DESTINATION .+\\):DESTINATION $(get_bashcompdir)\\):" \
 209                 src/bash_completion/CMakeLists.txt || die
 210
 211         # remove tests that need root access
 212         rm src/test/cli/ceph-authtool/cap*.t || die
 213 }
 214
 215 ceph_src_configure() {
 216         local flag
 217         local mycmakeargs=(
 218                 -DWITH_BABELTRACE=$(usex babeltrace)
 219                 -DWITH_CEPHFS=$(usex cephfs)
 220                 -DWITH_CEPHFS_SHELL=$(if python_is_python3; then usex cephfs; else echo OFF; fi)
 221                 -DWITH_DPDK=$(usex dpdk)
 222                 -DWITH_DPDK=$(usex spdk)
 223                 -DWITH_FUSE=$(usex fuse)
 224                 -DWITH_LTTNG=$(usex lttng)
 225                 -DWITH_GSSAPI=$(usex kerberos)
 226                 -DWITH_GRAFANA=$(usex grafana)
 227                 -DWITH_MGR=$(usex mgr)
 228                 -DWITH_MGR_DASHBOARD_FRONTEND=NO
 229                 -DWITH_NUMA=$(usex numa)
 230                 -DWITH_OPENLDAP=$(usex ldap)
 231                 -DMGR_PYTHON_VERSION=$(if python_is_python3; then echo 3; else echo 2; fi)
 232                 -DWITH_PYTHON3=$(if python_is_python3; then echo "ON"; else echo "OFF"; fi)
 233                 -DWITH_PYTHON2=$(if python_is_python3; then echo "OFF"; else echo "ON"; fi)
 234                 -DWITH_RADOSGW=$(usex radosgw)
 235                 -DWITH_RADOSGW_AMQP_ENDPOINT=$(usex rabbitmq)
 236                 -DWITH_SSL=$(usex ssl)
 237                 -DWITH_SYSTEMD=$(usex systemd)
 238                 -DWITH_TESTS=$(usex test)
 239                 -DWITH_XFS=$(usex xfs)
 240                 -DWITH_ZFS=$(usex zfs)
 241                 -DENABLE_SHARED='ON'
 242                 -DALLOCATOR=$(usex tcmalloc 'tcmalloc' "$(usex jemalloc 'jemalloc' 'libc')")
 243                 -DWITH_SYSTEM_BOOST=$(usex system-boost)
 244                 -DBOOST_J=$(makeopts_jobs)
 245                 -DWITH_RDMA=no
 246                 -DWITH_TBB=no
 247                 -DSYSTEMD_UNITDIR=$(systemd_get_systemunitdir)
 248                 -DEPYTHON_VERSION="${EPYTHON#python}"
 249                 -DCMAKE_INSTALL_DOCDIR="${EPREFIX}/usr/share/doc/${PN}-${PVR}"
 250                 -DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
 251                 #-Wno-dev
 252         )
 253         if use amd64 || use x86; then
 254                 for flag in ${CPU_FLAGS_X86[@]}; do
 255                         mycmakeargs+=("$(usex cpu_flags_x86_${flag} "-DHAVE_INTEL_${flag^^}=1")")
 256                 done
 257         fi
 258
 259         rm -f "${BUILD_DIR:-${S}}/CMakeCache.txt" \
 260                 || die "failed to remove cmake cache"
 261
 262         cmake-utils_src_configure
 263
 264         # bug #630232
 265         sed -i "s:\"${T//:\\:}/${EPYTHON}/bin/python\":\"${PYTHON}\":" \
 266                 "${BUILD_DIR:-${S}}"/include/acconfig.h \
 267                 || die "sed failed"
 268 }
 269
 270 src_configure() {
 271         use custom-cflags || strip-flags
 272         ceph_src_configure
 273 }
 274
 275 python_compile() {
 276         local CMAKE_USE_DIR="${S}"
 277         ceph_src_configure
 278
 279         pushd "${BUILD_DIR}/src/pybind" >/dev/null || die
 280         emake VERBOSE=1 clean
 281         emake VERBOSE=1 all
 282
 283         # python modules are only compiled with "make install" so we need to do this to
 284         # prevent doing a bunch of compilation in src_install
 285         DESTDIR="${T}" emake VERBOSE=1 install
 286         popd >/dev/null || die
 287 }
 288
 289 src_compile() {
 290         cmake-utils_src_make VERBOSE=1 all
 291
 292         # we have to do this here to prevent from building everything multiple times
 293         python_copy_sources
 294         python_foreach_impl python_compile
 295 }
 296
 297 src_test() {
 298         make check || die "make check failed"
 299 }
 300
 301 python_install() {
 302         local CMAKE_USE_DIR="${S}"
 303         pushd "${BUILD_DIR}/src/pybind" >/dev/null || die
 304         DESTDIR="${ED}" emake VERBOSE=1 install
 305         popd >/dev/null || die
 306
 307         python_optimize
 308 }
 309
 310 src_install() {
 311         cmake-utils_src_install
 312         python_foreach_impl python_install
 313
 314         find "${ED}" -name '*.la' -type f -delete || die
 315
 316         exeinto /usr/$(get_libdir)/ceph
 317         newexe "${BUILD_DIR}/bin/init-ceph" init-ceph
 318
 319         insinto /etc/logrotate.d/
 320         newins "${FILESDIR}"/ceph.logrotate-r2 ${PN}
 321
 322         keepdir /var/lib/${PN}{,/tmp} /var/log/${PN}/stat
 323
 324         fowners -R ceph:ceph /var/log/ceph
 325
 326         newinitd "${FILESDIR}/rbdmap.initd" rbdmap
 327         newinitd "${FILESDIR}/${PN}.initd-r12" ${PN}
 328         newconfd "${FILESDIR}/${PN}.confd-r5" ${PN}
 329
 330         insinto /etc/sysctl.d
 331         newins "${FILESDIR}"/sysctld 90-${PN}.conf
 332
 333         use tcmalloc && newenvd "${FILESDIR}"/envd-tcmalloc 99${PN}-tcmalloc
 334
 335         # units aren't installed by the build system unless systemd is enabled
 336         # so no point installing these with the USE flag disabled
 337         if use systemd; then
 338                 systemd_install_serviced "${FILESDIR}/ceph-mds_at.service.conf" \
 339                         "ceph-mds@.service"
 340
 341                 systemd_install_serviced "${FILESDIR}/ceph-osd_at.service.conf" \
 342                         "ceph-osd@.service"
 343         fi
 344
 345         udev_dorules udev/*.rules
 346
 347         readme.gentoo_create_doc
 348
 349         python_setup 'python3*'
 350
 351         # bug #630232
 352         sed -i -r "s:${T//:/\\:}/${EPYTHON}:/usr:" "${ED}"/usr/bin/ceph{,-crash} \
 353                 || die "sed failed"
 354
 355         python_fix_shebang "${ED}"/usr/{,s}bin/
 356
 357         # python_fix_shebang apparently is not idempotent
 358         local shebang_regex='(/usr/lib/python-exec/python[0-9]\.[0-9]/python)[0-9]\.[0-9]'
 359         grep -r -E -l --null "${shebang_regex}" "${ED}"/usr/{s,}bin/ \
 360                 | xargs --null --no-run-if-empty -- sed -i -r  "s:${shebang_regex}:\1:" || die
 361
 362         local -a rados_classes=( "${ED}/usr/$(get_libdir)/rados-classes"/* )
 363         dostrip -x "${rados_classes[@]#${ED}}"
 364 }
 365
 366 pkg_postinst() {
 367         readme.gentoo_print_elog
 368 }