sys-boot/palo/palo-2.12-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit toolchain-funcs
   6
   7 DESCRIPTION="PALO : PArisc Linux Loader"
   8 HOMEPAGE="http://parisc-linux.org/ https://parisc.wiki.kernel.org/"
   9 SRC_URI="https://git.kernel.org/pub/scm/linux/kernel/git/deller/${PN}.git/snapshot/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="-* hppa"
  14
  15 PATCHES=(
  16         "${FILESDIR}"/${PN}-2.00-toolchain.patch
  17         "${FILESDIR}"/${PN}-2.12-gcc10.patch
  18 )
  19
  20 src_compile() {
  21         local target
  22         for target in '-C palo' '-C ipl' 'iplboot'; do
  23                 emake AR=$(tc-getAR) CC=$(tc-getCC) LD=$(tc-getLD) ${target}
  24         done
  25 }
  26
  27 src_install() {
  28         into /
  29         dosbin palo/palo
  30
  31         insinto /usr/share/palo
  32         doins iplboot
  33
  34         insinto /etc
  35         doins "${FILESDIR}"/palo.conf
  36
  37         insinto /etc/kernel/postinst.d
  38         insopts -m 0744
  39         doins "${FILESDIR}"/99palo
  40
  41         doman palo.8
  42
  43         dodoc TODO debian/changelog README.html
  44 }