sys-boot/palo/palo-1.92.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils flag-o-matic toolchain-funcs
   8
   9 DESCRIPTION="PALO : PArisc Linux Loader"
  10 HOMEPAGE="http://parisc-linux.org/ https://parisc.wiki.kernel.org/"
  11 SRC_URI="https://dev.gentoo.org/~jer/${P/-/_}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="-* hppa"
  16 IUSE=""
  17
  18 src_prepare() {
  19         epatch \
  20                 "${FILESDIR}"/${PN}-1.92-toolchain.patch
  21         sed -i palo/Makefile -e '/^LDFLAGS=/d' || die
  22 }
  23
  24 src_compile() {
  25         local target
  26         for target in '-C palo' '-C ipl' 'iplboot'; do
  27                 emake AR=$(tc-getAR) CC=$(tc-getCC) LD=$(tc-getLD) ${target}
  28         done
  29 }
  30
  31 src_install() {
  32         into /
  33         dosbin palo/palo
  34
  35         doman palo.8
  36         dohtml README.html
  37         dodoc Changes TODO debian/changelog
  38
  39         insinto /etc
  40         doins "${FILESDIR}"/palo.conf
  41
  42         insinto /usr/share/palo
  43         doins iplboot
  44
  45         insinto /etc/kernel/postinst.d/
  46         INSOPTIONS="-m 0744" doins "${FILESDIR}"/99palo
  47 }