sys-block/nbd/nbd-3.18.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 DESCRIPTION="Userland client/server for kernel network block device"
   7 HOMEPAGE="http://nbd.sourceforge.net/"
   8 if [[ "${PV}" = 9999 ]] ; then
   9         inherit autotools git-r3
  10         EGIT_REPO_URI="https://github.com/NetworkBlockDevice/nbd.git"
  11 else
  12         SRC_URI="mirror://sourceforge/nbd/${P}.tar.xz"
  13         KEYWORDS="~alpha amd64 arm hppa ~ia64 ppc ppc64 ~sparc x86"
  14 fi
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 IUSE="debug gnutls netlink zlib"
  18
  19 RDEPEND="
  20         >=dev-libs/glib-2.26.0
  21         gnutls? ( >=net-libs/gnutls-2.12.0 )
  22         netlink? ( >=dev-libs/libnl-3.1 )
  23         zlib? ( sys-libs/zlib )
  24 "
  25 DEPEND="${RDEPEND}
  26         virtual/pkgconfig
  27 "
  28
  29 if [[ "${PV}" = 9999 ]] ; then
  30         DEPEND+="
  31                 app-text/docbook-sgml-dtd:4.5
  32                 app-text/docbook-sgml-utils
  33         "
  34 fi
  35
  36 src_prepare() {
  37         default
  38         if [[ "${PV}" = 9999 ]] ; then
  39                 emake -C man -f Makefile.am \
  40                         nbd-server.1.sh.in \
  41                         nbd-server.5.sh.in \
  42                         nbd-client.8.sh.in \
  43                         nbd-trdump.1.sh.in \
  44                         nbdtab.5.sh.in
  45                 emake -C systemd -f Makefile.am nbd@.service.sh.in
  46                 eautoreconf
  47         fi
  48 }
  49
  50 src_configure() {
  51         local myeconfargs=(
  52                 --enable-lfs
  53                 $(use_enable !debug syslog)
  54                 $(use_enable debug)
  55                 $(use_enable zlib gznbd)
  56                 $(use_with gnutls)
  57                 $(use_with netlink libnl)
  58         )
  59         econf "${myeconfargs[@]}"
  60 }