sys-block/hpacucli/hpacucli-9.40.12.0.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit rpm versionator pax-utils
   7
   8 MY_PV=$(replace_version_separator 2 '-')
   9
  10 SRC_URI_BASE="ftp://ftp.hp.com/pub/softlib2/software1/pubsw-linux"
  11 AMD64_PID="1257348637"
  12 AMD64_VID="80070"
  13 X86_PID="414707558"
  14 X86_VID="80071"
  15
  16 DESCRIPTION="HP Array Config Utility Command Line Interface (HPACUCLI, formerly CPQACUXE)"
  17 HOMEPAGE="http://h18000.www1.hp.com/products/servers/linux/documentation.html"
  18 SRC_URI="
  19         amd64? ( ${SRC_URI_BASE}/p${AMD64_PID}/v${AMD64_VID}/${PN}-${MY_PV}.x86_64.rpm )
  20         x86? ( ${SRC_URI_BASE}/p${X86_PID}/v${X86_VID}/${PN}-${MY_PV}.i386.rpm )"
  21
  22 LICENSE="hp-proliant-essentials"
  23 SLOT="0"
  24 KEYWORDS="-* amd64 x86"
  25 IUSE=""
  26
  27 DEPEND=""
  28 RDEPEND="sys-apps/coreutils
  29         sys-process/procps
  30         >=sys-apps/util-linux-2.20.1"
  31
  32 S="${WORKDIR}"
  33
  34 HPACUCLI_BASEDIR="/opt/hp/hpacucli"
  35 QA_PREBUILT="${HPACUCLI_BASEDIR:1}/*"
  36 QA_EXECSTACK="${HPACUCLI_BASEDIR:1}/libcpqimgr*.so"
  37
  38 src_install() {
  39         local MY_S="${S}/opt/compaq/${PN}/bld"
  40
  41         newsbin "${FILESDIR}"/"${PN}-wrapper-r1" hpacucli
  42         dosym /usr/sbin/hpacucli /usr/sbin/hpacuscripting
  43
  44         exeinto "${HPACUCLI_BASEDIR}"
  45         for bin in "${MY_S}"/.hp*; do
  46                 local basename=$(basename "${bin}")
  47                 newexe "${bin}" ${basename#.}.bin
  48         done
  49
  50         insinto "${HPACUCLI_BASEDIR}"
  51         doins "${MY_S}"/*.so
  52
  53         dodoc "${MY_S}"/*.txt
  54         doman "${S}"/usr/man/man*/*
  55
  56         cat <<-EOF >"${T}"/45${PN}
  57                 LDPATH=${HPACUCLI_BASEDIR}
  58                 EOF
  59         doenvd "${T}"/45${PN}
  60
  61         pax-mark m "${D}opt/hp/hpacucli/"*
  62 }