sys-block/blocks/blocks-0.1.4_pre131210-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 PYTHON_COMPAT=( python3_{3,4} )
   8
   9 inherit distutils-r1
  10
  11 DESCRIPTION="Conversion tools for block devices"
  12 HOMEPAGE="https://github.com/g2p/blocks"
  13 SRC_URI="https://dev.gentoo.org/~jlec/distfiles/${P}.tar.xz"
  14
  15 SLOT="0"
  16 LICENSE="GPL-3+"
  17 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  18 IUSE="+minimal"
  19
  20 DEPEND="
  21         dev-python/maintboot
  22         >=dev-python/pyparted-3.10[${PYTHON_USEDEP}]
  23         >=dev-python/python-augeas-0.5.0[${PYTHON_USEDEP}]
  24 "
  25 RDEPEND="${DEPEND}
  26         >=sys-block/parted-2.3
  27         !minimal? (
  28                 sys-fs/btrfs-progs
  29                 sys-fs/lvm2
  30                 sys-fs/bcache-tools
  31                 sys-fs/nilfs-utils
  32                 sys-fs/cryptsetup
  33                 sys-fs/reiserfsprogs
  34                 sys-fs/xfsprogs
  35                 sys-fs/e2fsprogs
  36         )
  37 "
  38
  39 # NEVER, EVER run filesystem tests during build
  40 RESTRICT="test"
  41
  42 python_test() {
  43         cd tests || die
  44         emake
  45 }
  46
  47 pkg_postinst() {
  48         if use minimal; then
  49                 einfo "For filesystem support you need to install:"
  50                 echo
  51                 einfo "btrfs:        sys-fs/btrfs-progs"
  52                 einfo "LVM:          sys-fs/lvm2"
  53                 einfo "bcache:       sys-fs/bcache-tools"
  54                 einfo "NILFS:        sys-fs/nilfs-utils"
  55                 einfo "crypted FS:   sys-fs/cryptsetup"
  56                 einfo "reiser:       sys-fs/reiserfsprogs"
  57                 einfo "XFS:          sys-fs/xfsprogs"
  58                 einfo "EXT2/3/4:     sys-fs/e2fsprogs"
  59                 echo
  60         fi
  61 }