sys-block/blktrace/blktrace-1.2.0.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit toolchain-funcs flag-o-matic linux-info
   7
   8 MY_PN="blktrace"
   9 MY_P="${MY_PN}-${PV}"
  10
  11 DESCRIPTION="show detailed info about what is happening on a block device io queue"
  12 HOMEPAGE="http://git.kernel.dk/cgit/blktrace/"
  13 SRC_URI="http://brick.kernel.dk/snaps/${MY_P}.tar.bz2"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="amd64 ~arm ppc x86"
  18 IUSE="doc"
  19
  20 RDEPEND="dev-libs/libaio"
  21 # This is a Linux specific app!
  22 DEPEND="${RDEPEND}
  23         sys-kernel/linux-headers
  24         doc? (
  25                 virtual/latex-base
  26                 >=app-text/texlive-core-2014
  27         )
  28 "
  29 S="${WORKDIR}/${MY_P}"
  30
  31 CONFIG_CHECK="~BLK_DEV_IO_TRACE"
  32 WARNING_BLK_DEV_IO_TRACE="you need to enable BLK_DEV_IO_TRACE kernel option if you want to gather traces from this machine"
  33
  34 PATCHES=(
  35         "${FILESDIR}"/${P}-overlapping-io-stats.patch
  36         "${FILESDIR}"/${PN}-1.2.0-ldflags.patch #335741
  37         "${FILESDIR}"/${PN}-1.2.0-parallel-build.patch #335741
  38 )
  39
  40 src_compile() {
  41         append-cppflags -DLVM_REMAP_WORKAROUND -W -I"${S}"
  42         emake CC="$(tc-getCC)" CFLAGS="${CFLAGS} ${CPPFLAGS}"
  43         if use doc; then
  44                 export VARTEXFONTS="${T}/fonts"
  45                 emake docs
  46         fi
  47 }
  48
  49 src_install() {
  50         emake install DESTDIR="${ED}" prefix="/usr" mandir="/usr/share/man"
  51         einstalldocs
  52         use doc && dodoc doc/blktrace.pdf btt/doc/btt.pdf
  53 }