sys-auth/rtkit/rtkit-0.13-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit linux-info meson
   7
   8 DESCRIPTION="Realtime Policy and Watchdog Daemon"
   9 HOMEPAGE="https://github.com/heftig/rtkit"
  10 SRC_URI="https://github.com/heftig/${PN}/releases/download/v${PV}/${P}.tar.xz"
  11
  12 LICENSE="GPL-3 BSD"
  13 SLOT="0"
  14 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
  15 IUSE="systemd"
  16
  17 BDEPEND="virtual/pkgconfig"
  18 DEPEND="acct-group/rtkit
  19         acct-user/rtkit
  20         sys-apps/dbus
  21         sys-auth/polkit
  22         sys-libs/libcap
  23         systemd? ( sys-apps/systemd )"
  24 RDEPEND="${DEPEND}"
  25
  26 PATCHES=(
  27         "${FILESDIR}"/${PN}-0.13_meson_rtkitctl_dir.patch
  28         "${FILESDIR}"/${PN}-0.13_meson_xxd_optional.patch
  29 )
  30
  31 pkg_pretend() {
  32         if use kernel_linux; then
  33                 CONFIG_CHECK="~!RT_GROUP_SCHED"
  34                 ERROR_RT_GROUP_SCHED="CONFIG_RT_GROUP_SCHED is enabled. rtkit-daemon (or any other "
  35                 ERROR_RT_GROUP_SCHED+="real-time task) will not work unless run as root. Please consider "
  36                 ERROR_RT_GROUP_SCHED+="unsetting this option."
  37                 check_extra_config
  38         fi
  39 }
  40
  41 src_configure() {
  42         local emesonargs=(
  43                 -Dinstalled_tests=false
  44                 $(meson_feature systemd libsystemd)
  45         )
  46         meson_src_configure
  47 }