sys-auth/pam_mktemp/pam_mktemp-1.1.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit toolchain-funcs pam
   7
   8 DESCRIPTION="Create per-user private temporary directories during login"
   9 HOMEPAGE="http://www.openwall.com/pam/"
  10 SRC_URI="http://www.openwall.com/pam/modules/${PN}/${P}.tar.gz"
  11
  12 LICENSE="BSD-2" # LICENSE file says "heavily cut-down 'BSD license'"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 m68k ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux"
  15 IUSE="selinux +prevent-removal"
  16
  17 RDEPEND="sys-libs/pam
  18         selinux? ( sys-libs/libselinux )"
  19
  20 DEPEND="${RDEPEND}
  21         prevent-removal? ( sys-kernel/linux-headers )"
  22
  23 src_prepare() {
  24         default
  25         eapply "${FILESDIR}"/${P}-e2fsprogs-libs.patch
  26 }
  27
  28 src_compile() {
  29         emake \
  30                 CC="$(tc-getCC)" \
  31                 CFLAGS="${CFLAGS} -fPIC" \
  32                 LDFLAGS="${LDFLAGS} --shared -Wl,--version-script,\$(MAP)" \
  33                 USE_SELINUX="$(use selinux && echo 1 || echo 0)" \
  34                 USE_APPEND_FL="$(use prevent-removal && echo 1 || echo 0)"
  35 }
  36
  37 src_install() {
  38         dopammod pam_mktemp.so
  39         dodoc README
  40 }