sys-auth/libnss-mysql/libnss-mysql-1.5_p20060915-r2.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=2
   5
   6 inherit eutils multilib autotools
   7
   8 KEYWORDS="amd64 ppc ~sparc x86"
   9
  10 DESCRIPTION="NSS MySQL Library"
  11 HOMEPAGE="http://libnss-mysql.sourceforge.net/"
  12 SRC_URI="http://libnss-mysql.sourceforge.net/snapshot/${PN}-${PV/1.5_p/}.tgz"
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 IUSE="debug"
  16
  17 DEPEND="virtual/mysql"
  18 RDEPEND="${DEPEND}"
  19 S="${WORKDIR}/${PN}"
  20
  21 src_prepare() {
  22         epatch "${FILESDIR}"/${P}-no-automagic-debug.diff
  23         eautoconf
  24 }
  25
  26 src_configure() {
  27         # Usually, authentication libraries don't belong into usr.
  28         # But here, it's required that the lib is in the same dir
  29         # as libmysql, because else failures may occur on boot if
  30         # udev tries to access a user / group that doesn't exist
  31         # on the system before /usr is mounted.
  32         econf --libdir="/usr/$(get_libdir)" \
  33                 $(use_enable debug)
  34 }
  35
  36 src_install() {
  37         emake DESTDIR="${D}" install || die
  38
  39         find "${D}" -name '*.la' -delete
  40
  41         newdoc sample/README README.sample
  42         dodoc AUTHORS DEBUGGING FAQ INSTALL NEWS README THANKS \
  43                 TODO UPGRADING ChangeLog
  44
  45         for subdir in sample/{linux,freebsd,complex,minimal} ; do
  46                 docinto "${subdir}"
  47                 dodoc "${subdir}/"{*.sql,*.cfg}
  48         done
  49 }