sys-apps/ucspi-ssl/ucspi-ssl-0.99e.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit fixheadtails qmail
   7
   8 DESCRIPTION="Command-line tools for building SSL client-server applications"
   9 HOMEPAGE="https://www.fehcom.de/ipnet/ucspi-ssl.html"
  10 SRC_URI="https://www.fehcom.de/ipnet/ucspi-ssl/${P}.tgz"
  11
  12 LICENSE="public-domain"
  13 SLOT="0"
  14 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sparc ~x86"
  15 IUSE="bindist perl libressl"
  16
  17 DEPEND="libressl? ( dev-libs/libressl:0= )
  18         !libressl? ( dev-libs/openssl:0=[bindist=] )
  19         perl? ( dev-lang/perl:= )"
  20 RDEPEND="${DEPEND}
  21         sys-apps/ucspi-tcp"
  22
  23 S="${WORKDIR}"/host/superscript.com/net/${P}
  24
  25 src_prepare() {
  26         ht_fix_all
  27
  28         sed -i -e 's:auto:gcc:' conf-cc || die
  29         sed -i -e 's:-m64::' conf-ld || die
  30         qmail_set_cc
  31
  32         echo "/usr/bin" > conf-tcpbin || die
  33         echo "/usr/share/ca-certificates/" > conf-cadir || die
  34         echo "${QMAIL_HOME}/control/dh1024.pem" > conf-dhfile || die
  35         echo "/usr/" > src/home || die
  36         sed -i -e 's:HOME/command:/usr/bin:' \
  37                 src/sslcat.sh src/sslconnect.sh src/https\@.sh || die
  38
  39         # workaround: SSL_TXT_ECDH is always set in openssl/ssl.h, even with openssl[bindist]
  40         sed -i -e 's:SSL_TXT_ECDH:ENABLE_SSL_TXT_ECDH:' src/ucspissl.h src/ssl_params.c conf-ecdh || die
  41         if use bindist; then
  42                 echo > conf-ecdh || die
  43         fi
  44
  45         eapply_user
  46 }
  47
  48 src_compile() {
  49         cd src || die
  50         emake sysdeps
  51         emake uint32.h
  52         emake
  53 }
  54
  55 src_install() {
  56         dodoc -r doc/.
  57         doman man/*
  58
  59         cd src || die
  60         dobin $(<../package/commands-base)
  61         use perl && dobin $(<../package/commands-sslperl)
  62 }