sys-apps/s6-rc/s6-rc-0.3.0.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit versionator
   7
   8 DESCRIPTION="service manager for the s6 supervision suite"
   9 HOMEPAGE="https://www.skarnet.org/software/s6-rc/"
  10 SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
  11
  12 LICENSE="ISC"
  13 SLOT="0/$(get_version_component_range 1-2)"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE="static static-libs"
  16
  17 DEPEND=">=sys-devel/make-3.81
  18         static? (
  19                 >=dev-lang/execline-2.3.0.3[static-libs]
  20                 >=dev-libs/skalibs-2.6.0.1[static-libs]
  21                 >=sys-apps/s6-2.6.1.1[static-libs]
  22         )
  23         !static? (
  24                 >=dev-lang/execline-2.3.0.3[static=]
  25                 >=dev-libs/skalibs-2.6.0.1
  26                 >=sys-apps/s6-2.6.1.1[static=]
  27         )
  28 "
  29 RDEPEND="
  30         >=dev-lang/execline-2.3.0.3:=[!static?]
  31         >=sys-apps/s6-2.6.1.1:=[!static?]
  32         !static? (
  33                 >=dev-libs/skalibs-2.6.0.1:=
  34         )
  35 "
  36
  37 DOCS="examples"
  38 HTML_DOCS="doc/*"
  39
  40 src_prepare() {
  41         default
  42
  43         # Remove QA warning about LDFLAGS addition
  44         sed -i "s/tryldflag LDFLAGS_AUTO -Wl,--hash-style=both/:/" "${S}/configure" || die
  45
  46         # configure overrides gentoo's -fstack-protector default
  47         sed -i "/^tryflag CFLAGS -fno-stack-protector$/d" "${S}/configure" || die
  48 }
  49
  50 src_configure() {
  51         econf \
  52                 --bindir=/bin \
  53                 --dynlibdir=/$(get_libdir) \
  54                 --libdir=/usr/$(get_libdir)/${PN} \
  55                 --with-dynlib=/$(get_libdir) \
  56                 --with-lib=/usr/$(get_libdir)/execline \
  57                 --with-lib=/usr/$(get_libdir)/s6 \
  58                 --with-lib=/usr/$(get_libdir)/skalibs \
  59                 --with-sysdeps=/usr/$(get_libdir)/skalibs \
  60                 $(use_enable !static shared) \
  61                 $(use_enable static allstatic) \
  62                 $(use_enable static static-libc) \
  63                 $(use_enable static-libs static)
  64 }