sys-apps/s6-portable-utils/s6-portable-utils-2.2.1.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="Set of tiny portable unix utilities"
   7 HOMEPAGE="https://www.skarnet.org/software/s6-portable-utils/"
   8 SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
   9
  10 LICENSE="ISC"
  11 SLOT="0"
  12 KEYWORDS="~amd64 ~x86"
  13 IUSE="static"
  14
  15 RDEPEND="!static? ( >=dev-libs/skalibs-2.8.0.0:= )"
  16 DEPEND="${RDEPEND}
  17         static? ( >=dev-libs/skalibs-2.8.0.0[static-libs] )
  18 "
  19
  20 HTML_DOCS=( doc/. )
  21
  22 src_prepare() {
  23         default
  24
  25         # Avoid QA warning for LDFLAGS addition; avoid overriding -fstack-protector
  26         sed -i -e 's/.*-Wl,--hash-style=both$/:/' -e '/-fno-stack-protector$/d' \
  27                 configure || die
  28 }
  29
  30 src_configure() {
  31         econf \
  32                 --bindir=/bin \
  33                 --dynlibdir=/usr/$(get_libdir) \
  34                 --libdir=/usr/$(get_libdir)/${PN} \
  35                 --with-dynlib=/usr/$(get_libdir) \
  36                 --with-lib=/usr/$(get_libdir)/skalibs \
  37                 --with-sysdeps=/usr/$(get_libdir)/skalibs \
  38                 $(use_enable static allstatic) \
  39                 $(use_enable static static-libc)
  40 }