sys-apps/s6-linux-init/s6-linux-init-1.0.3.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="Generates an init binary for s6-based init systems"
   7 HOMEPAGE="https://www.skarnet.org/software/s6-linux-init/"
   8 SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
   9
  10 LICENSE="ISC"
  11 SLOT="0/$(ver_cut 1-2)"
  12 KEYWORDS="~amd64 ~x86"
  13 IUSE="static static-libs +sysv-utils"
  14
  15 REQUIRED_USE="static? ( static-libs )"
  16
  17 RDEPEND=">=dev-lang/execline-2.5.3.0:=[static-libs?]
  18         >=dev-libs/skalibs-2.9.1.0:=[static-libs?]
  19         >=sys-apps/s6-2.9.0.1:=[static-libs?]
  20         sysv-utils? (
  21                 !sys-apps/systemd[sysv-utils]
  22                 !sys-apps/sysvinit
  23         )
  24 "
  25 DEPEND="${RDEPEND}"
  26
  27 HTML_DOCS=( doc/. )
  28
  29 src_prepare() {
  30         default
  31
  32         # Avoid QA warning for LDFLAGS addition; avoid overriding -fstack-protector
  33         sed -i -e 's/.*-Wl,--hash-style=both$/:/' -e '/-fno-stack-protector$/d' \
  34                 configure || die
  35 }
  36
  37 src_configure() {
  38         econf \
  39                 --bindir=/bin \
  40                 --dynlibdir=/usr/$(get_libdir) \
  41                 --skeldir=/etc/s6-linux-init/skel \
  42                 --libdir=/usr/$(get_libdir)/${PN} \
  43                 --with-dynlib=/usr/$(get_libdir) \
  44                 --with-lib=/usr/$(get_libdir)/s6 \
  45                 --with-lib=/usr/$(get_libdir)/skalibs \
  46                 --with-sysdeps=/usr/$(get_libdir)/skalibs \
  47                 --enable-shared \
  48                 $(use_enable static allstatic) \
  49                 $(use_enable static static-libc) \
  50                 $(use_enable static-libs static)
  51 }
  52
  53 src_install() {
  54         default
  55
  56         if use sysv-utils ; then
  57                 "${D}/bin/s6-linux-init-maker" -f "${D}/etc/s6-linux-init/skel" "${T}/dir" || die
  58                 into /
  59                 dosbin "${T}/dir/bin"/{halt,poweroff,reboot,shutdown,telinit}
  60         fi
  61 }
  62
  63 pkg_postinst() {
  64         einfo "Read ${EROOT}/usr/share/doc/${PF}/html/quickstart.html"
  65         einfo "for usage instructions."
  66 }