sys-apps/s6/s6-2.9.0.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="skarnet.org's small and secure supervision software suite"
   7 HOMEPAGE="https://www.skarnet.org/software/s6/"
   8 SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
   9
  10 LICENSE="ISC"
  11 SLOT="0/$(ver_cut 1-2)"
  12 KEYWORDS="~amd64 ~arm ~x86"
  13 IUSE="static static-libs"
  14
  15 REQUIRED_USE="static? ( static-libs )"
  16
  17 RDEPEND=">=dev-lang/execline-2.5.3.0:=[static-libs?]
  18         >=dev-libs/skalibs-2.9.1.0:=[static-libs?]
  19 "
  20 DEPEND="${RDEPEND}"
  21
  22 HTML_DOCS=( doc/. )
  23
  24 src_prepare() {
  25         default
  26
  27         # Avoid QA warning for LDFLAGS addition; avoid overriding -fstack-protector
  28         sed -i -e 's/.*-Wl,--hash-style=both$/:/' -e '/-fno-stack-protector$/d' \
  29                 configure || die
  30 }
  31
  32 src_configure() {
  33         econf \
  34                 --bindir=/bin \
  35                 --dynlibdir=/usr/$(get_libdir) \
  36                 --libdir=/usr/$(get_libdir)/${PN} \
  37                 --with-dynlib=/usr/$(get_libdir) \
  38                 --with-lib=/usr/$(get_libdir)/execline \
  39                 --with-lib=/usr/$(get_libdir)/skalibs \
  40                 --with-sysdeps=/usr/$(get_libdir)/skalibs \
  41                 --enable-shared \
  42                 $(use_enable static allstatic) \
  43                 $(use_enable static static-libc) \
  44                 $(use_enable static-libs static)
  45 }