sys-apps/s6/s6-2.7.0.0.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit versionator
   7
   8 DESCRIPTION="skarnet.org's small and secure supervision software suite"
   9 HOMEPAGE="https://www.skarnet.org/software/s6/"
  10 SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
  11
  12 LICENSE="ISC"
  13 SLOT="0/$(get_version_component_range 1-2)"
  14 KEYWORDS="~amd64 ~arm ~x86"
  15 IUSE="static static-libs"
  16
  17 DEPEND=">=sys-devel/make-3.81
  18         static? (
  19                 >=dev-lang/execline-2.3.0.4[static-libs]
  20                 >=dev-libs/skalibs-2.6.3.0[static-libs]
  21         )
  22         !static? (
  23                 >=dev-lang/execline-2.3.0.4[static=]
  24                 >=dev-libs/skalibs-2.6.3.0
  25         )
  26 "
  27 RDEPEND="
  28         >=dev-lang/execline-2.3.0.4:=[!static?]
  29         !static? (
  30                 >=dev-libs/skalibs-2.6.3.0:=
  31         )
  32 "
  33
  34 DOCS="AUTHORS examples README*"
  35 HTML_DOCS="doc/*"
  36
  37 src_prepare() {
  38         default
  39
  40         # Remove QA warning about LDFLAGS addition
  41         sed -i "s/tryldflag LDFLAGS_AUTO -Wl,--hash-style=both/:/" "${S}/configure" || die
  42
  43         # configure overrides gentoo's -fstack-protector default
  44         sed -i "/^tryflag CFLAGS -fno-stack-protector$/d" "${S}/configure" || die
  45 }
  46
  47 src_configure() {
  48         econf \
  49                 --bindir=/bin \
  50                 --dynlibdir=/$(get_libdir) \
  51                 --libdir=/usr/$(get_libdir)/${PN} \
  52                 --with-dynlib=/$(get_libdir) \
  53                 --with-lib=/usr/$(get_libdir)/execline \
  54                 --with-lib=/usr/$(get_libdir)/skalibs \
  55                 --with-sysdeps=/usr/$(get_libdir)/skalibs \
  56                 $(use_enable !static shared) \
  57                 $(use_enable static allstatic) \
  58                 $(use_enable static static-libc) \
  59                 $(use_enable static-libs static)
  60 }