sys-apps/pciutils/pciutils-3.5.6-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eapi7-ver multilib toolchain-funcs multilib-minimal flag-o-matic
   7
   8 DESCRIPTION="Various utilities dealing with the PCI bus"
   9 HOMEPAGE="https://mj.ucw.cz/sw/pciutils/ https://git.kernel.org/?p=utils/pciutils/pciutils.git"
  10 SRC_URI="https://mj.ucw.cz/download/linux/pci/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux"
  15 IUSE="dns +kmod static-libs +udev zlib"
  16
  17 # Have the sub-libs in RDEPEND with [static-libs] since, logically,
  18 # our libpci.a depends on libz.a/etc... at runtime.
  19 LIB_DEPEND="
  20         zlib? ( >=sys-libs/zlib-1.2.8-r1[static-libs(+),${MULTILIB_USEDEP}] )
  21         udev? ( >=virtual/libudev-208[static-libs(-),${MULTILIB_USEDEP}] )
  22 "
  23 DEPEND="
  24         kmod? ( sys-apps/kmod )
  25         static-libs? ( ${LIB_DEPEND} )
  26         !static-libs? ( ${LIB_DEPEND//static-libs([+-]),} )
  27 "
  28 RDEPEND="
  29         ${DEPEND}
  30         sys-apps/hwids
  31 "
  32 DEPEND="
  33         ${DEPEND}
  34         kmod? ( virtual/pkgconfig )
  35 "
  36
  37 PATCHES=(
  38         "${FILESDIR}"/${PN}-3.1.9-static-pc.patch
  39 )
  40
  41 MULTILIB_WRAPPED_HEADERS=( /usr/include/pci/config.h )
  42
  43 switch_config() {
  44         [[ $# -ne 2 ]] && return 1
  45         local opt=$1 val=$2
  46
  47         sed "s@^\(${opt}=\).*\$@\1${val}@" -i Makefile || die
  48         return 0
  49 }
  50
  51 src_prepare() {
  52         default
  53
  54         if use static-libs ; then
  55                 cp -pPR "${S}" "${S}.static" || die
  56                 mv "${S}.static" "${S}/static" || die
  57         fi
  58
  59         multilib_copy_sources
  60 }
  61
  62 multilib_src_configure() {
  63         append-lfs-flags #471102
  64 }
  65
  66 pemake() {
  67         emake \
  68                 HOST="${CHOST}" \
  69                 CROSS_COMPILE="${CHOST}-" \
  70                 CC="$(tc-getCC)" \
  71                 AR="$(tc-getAR)" \
  72                 PKG_CONFIG="$(tc-getPKG_CONFIG)" \
  73                 RANLIB="$(tc-getRANLIB)" \
  74                 DNS=$(usex dns) \
  75                 IDSDIR='$(SHAREDIR)/misc' \
  76                 MANDIR='$(SHAREDIR)/man' \
  77                 PREFIX="${EPREFIX}/usr" \
  78                 SHARED="yes" \
  79                 STRIP="" \
  80                 ZLIB=$(usex zlib) \
  81                 PCI_COMPRESSED_IDS=0 \
  82                 PCI_IDS=pci.ids \
  83                 LIBDIR="\${PREFIX}/$(get_libdir)" \
  84                 LIBKMOD=$(multilib_native_usex kmod) \
  85                 HWDB=$(usex udev) \
  86                 "$@"
  87 }
  88
  89 multilib_src_compile() {
  90         pemake OPT="${CFLAGS}" all
  91         if use static-libs ; then
  92                 pemake \
  93                         -C "${BUILD_DIR}/static" \
  94                         OPT="${CFLAGS}" \
  95                         SHARED="no" \
  96                         lib/libpci.a
  97         fi
  98 }
  99
 100 multilib_src_install() {
 101         pemake DESTDIR="${D}" install install-lib
 102         use static-libs && dolib.a "${BUILD_DIR}/static/lib/libpci.a"
 103 }
 104
 105 multilib_src_install_all() {
 106         dodoc ChangeLog README TODO
 107
 108         rm "${ED}"/usr/sbin/update-pciids "${ED}"/usr/share/misc/pci.ids \
 109                 "${ED}"/usr/share/man/man8/update-pciids.8*
 110
 111         newinitd "${FILESDIR}"/init.d-pciparm pciparm
 112         newconfd "${FILESDIR}"/conf.d-pciparm pciparm
 113 }
 114
 115 pkg_postinst() {
 116         if [[ ${REPLACING_VERSIONS} ]] && ver_test ${REPLACING_VERSIONS} -lt 3.2.0 ; then
 117                 elog "The 'network-cron' USE flag is gone; if you want a more up-to-date"
 118                 elog "pci.ids file, you should use sys-apps/hwids-99999999 (live ebuild)."
 119         fi
 120 }