sys-apps/less/less-561.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="Excellent text file viewer"
   7 HOMEPAGE="http://www.greenwoodsoftware.com/less/"
   8 SRC_URI="http://www.greenwoodsoftware.com/less/${P}.tar.gz"
   9
  10 LICENSE="|| ( GPL-3 BSD-2 )"
  11 SLOT="0"
  12 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  13 IUSE="pcre unicode"
  14
  15 DEPEND=">=app-misc/editor-wrapper-3
  16         >=sys-libs/ncurses-5.2:0=
  17         pcre? ( dev-libs/libpcre2 )"
  18 RDEPEND="${DEPEND}"
  19
  20 src_configure() {
  21         export ac_cv_lib_ncursesw_initscr=$(usex unicode)
  22         export ac_cv_lib_ncurses_initscr=$(usex !unicode)
  23         local myeconfargs=(
  24                 --with-regex=$(usex pcre pcre2 posix)
  25                 --with-editor="${EPREFIX}"/usr/libexec/editor
  26         )
  27         econf "${myeconfargs[@]}"
  28 }
  29
  30 src_install() {
  31         default
  32
  33         newbin "${FILESDIR}"/lesspipe.sh lesspipe
  34         newenvd "${FILESDIR}"/less.envd 70less
  35 }
  36
  37 pkg_preinst() {
  38         if has_version "<${CATEGORY}/${PN}-483-r1" ; then
  39                 elog "The lesspipe.sh symlink has been dropped.  If you are still setting"
  40                 elog "LESSOPEN to that, you will need to update it to '|lesspipe %s'."
  41                 elog "Colorization support has been dropped.  If you want that, check out"
  42                 elog "the new app-text/lesspipe package."
  43         fi
  44 }