sys-apps/irqbalance/irqbalance-1.6.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools systemd linux-info
   7
   8 DESCRIPTION="Distribute hardware interrupts across processors on a multiprocessor system"
   9 HOMEPAGE="https://github.com/Irqbalance/irqbalance"
  10 SRC_URI="https://github.com/Irqbalance/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~arm64 ppc ~ppc64 x86"
  15 IUSE="caps +numa selinux tui"
  16
  17 DEPEND="
  18         dev-libs/glib:2
  19         caps? ( sys-libs/libcap-ng )
  20         numa? ( sys-process/numactl )
  21         tui? ( sys-libs/ncurses:0=[unicode] )
  22 "
  23 BDEPEND="
  24         virtual/pkgconfig
  25 "
  26 RDEPEND="${DEPEND}
  27         selinux? ( sec-policy/selinux-irqbalance )
  28 "
  29
  30 pkg_setup() {
  31         CONFIG_CHECK="~PCI_MSI"
  32         linux-info_pkg_setup
  33 }
  34
  35 src_prepare() {
  36         # Follow systemd policies
  37         # https://wiki.gentoo.org/wiki/Project:Systemd/Ebuild_policy
  38         sed \
  39                 -e 's/ $IRQBALANCE_ARGS//' \
  40                 -e '/EnvironmentFile/d' \
  41                 -i misc/irqbalance.service || die
  42
  43         default
  44         eautoreconf
  45 }
  46
  47 src_configure() {
  48         local myeconfargs=(
  49                 $(use_with caps libcap-ng)
  50                 $(use_enable numa)
  51                 $(use_with tui irqbalance-ui)
  52         )
  53         econf "${myeconfargs[@]}"
  54 }
  55
  56 src_install() {
  57         default
  58
  59         newinitd "${FILESDIR}"/irqbalance.init.4 irqbalance
  60         newconfd "${FILESDIR}"/irqbalance.confd-1 irqbalance
  61         systemd_dounit misc/irqbalance.service
  62 }