sys-apps/gnome-disk-utility/gnome-disk-utility-3.34.5.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit gnome.org gnome2-utils meson xdg
   7
   8 DESCRIPTION="Disk Utility for GNOME using udisks"
   9 HOMEPAGE="https://wiki.gnome.org/Apps/Disks"
  10
  11 LICENSE="GPL-2+"
  12 SLOT="0"
  13 IUSE="fat elogind gnome systemd"
  14 REQUIRED_USE="?? ( elogind systemd )"
  15 KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc x86"
  16
  17 DEPEND="
  18         >=media-libs/libdvdread-4.2.0:0=
  19         >=dev-libs/glib-2.31:2
  20         >=x11-libs/gtk+-3.16.0:3
  21         >=media-libs/libcanberra-0.1[gtk3]
  22         >=app-arch/xz-utils-5.0.5
  23         >=x11-libs/libnotify-0.7:=
  24         >=app-crypt/libsecret-0.7
  25         >=dev-libs/libpwquality-1.0.0
  26         >=sys-fs/udisks-2.7.6:2
  27         elogind? ( >=sys-auth/elogind-209 )
  28         systemd? ( >=sys-apps/systemd-209:0= )
  29 "
  30 RDEPEND="${DEPEND}
  31         x11-themes/adwaita-icon-theme
  32         fat? ( sys-fs/dosfstools )
  33         gnome? ( >=gnome-base/gnome-settings-daemon-3.8 )
  34 "
  35 # libxml2 for xml-stripblanks in gresource
  36 BDEPEND="
  37         dev-libs/libxml2:2
  38         app-text/docbook-xsl-stylesheets
  39         dev-libs/libxslt
  40         dev-util/glib-utils
  41         >=sys-devel/gettext-0.19.8
  42         virtual/pkgconfig
  43 "
  44
  45 src_configure() {
  46         local emesonargs=(
  47                 -Dlogind=$(usex systemd libsystemd $(usex elogind libelogind none))
  48                 $(meson_use gnome gsd_plugin)
  49                 -Dman=true
  50         )
  51         meson_src_configure
  52 }
  53
  54 pkg_postinst() {
  55         xdg_pkg_postinst
  56         gnome2_schemas_update
  57 }
  58
  59 pkg_postrm() {
  60         xdg_pkg_postrm
  61         gnome2_schemas_update
  62 }