sys-apps/ethq/ethq-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 EGIT_REPO_URI="https://github.com/isc-projects/${PN}.git"
   7
   8 inherit git-r3 toolchain-funcs
   9
  10 DESCRIPTION="Ethernet NIC Queue stats viewer"
  11 HOMEPAGE="https://github.com/isc-projects/ethq"
  12 SRC_URI=""
  13
  14 LICENSE="MPL-2.0"
  15 SLOT="0"
  16 KEYWORDS=""
  17 IUSE="test"
  18 RESTRICT="!test? ( test )"
  19
  20 DEPEND="sys-libs/ncurses:0"
  21 RDEPEND="${DEPEND}"
  22
  23 src_prepare() {
  24         default
  25
  26         # Respect FLAGS
  27         sed -i \
  28                 -e '/CXXFLAGS/s/= -O3/+=/' \
  29                 -e 's/ -Werror//' \
  30                 -e '/LDFLAGS/s/=/+=/' Makefile || die "sed failed for Makefile"
  31
  32         if ! use test ; then
  33                 sed -i '/TARGETS/s/ethq_test//' Makefile \
  34                         || die "sed failed for USE flag test"
  35         fi
  36 }
  37
  38 src_compile() {
  39         # override for ncurses[tinfo]
  40         emake CXX="$(tc-getCXX)" LIBS_CURSES="$($(tc-getPKG_CONFIG) --libs ncurses)"
  41 }
  42
  43 src_test() {
  44         local driver
  45         for driver in tests/* ; do
  46                 "${S}"/ethq_test "${driver##*/}" "${driver}" \
  47                         || die "test failed on ${driver}"
  48         done
  49 }
  50
  51 src_install() {
  52         einstalldocs
  53         dobin ethq
  54 }