sys-apps/ethq/ethq-0.6.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 MY_PV=${PV//./_}
   7 MY_P=${PN}-${MY_PV}
   8
   9 inherit toolchain-funcs
  10
  11 DESCRIPTION="Ethernet NIC Queue stats viewer"
  12 HOMEPAGE="https://github.com/isc-projects/ethq"
  13 SRC_URI="https://github.com/isc-projects/ethq/archive/v${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
  14
  15 LICENSE="MPL-2.0"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="test"
  19 RESTRICT="!test? ( test )"
  20
  21 DEPEND="sys-libs/ncurses:0"
  22 RDEPEND="${DEPEND}"
  23
  24 S="${WORKDIR}/${MY_P}"
  25
  26 src_prepare() {
  27         default
  28
  29         # Respect FLAGS
  30         sed -i -e '/CXXFLAGS/s/= -O3/+=/' \
  31                 -e '/LDFLAGS/s/=/+=/' Makefile || die "sed failed for Makefile"
  32
  33         if ! use test ; then
  34                 sed -i '/TARGETS/s/ethq_test//' Makefile \
  35                         || die "sed failed for USE flag test"
  36         fi
  37 }
  38
  39 src_compile() {
  40         # override for ncurses[tinfo]
  41         emake CXX="$(tc-getCXX)" LIBS_CURSES="$($(tc-getPKG_CONFIG) --libs ncurses)"
  42 }
  43
  44 src_test() {
  45         local driver
  46         for driver in tests/* ; do
  47                 "${S}"/ethq_test "${driver##*/}" "${driver}" \
  48                         || die "test failed on ${driver}"
  49         done
  50 }
  51
  52 src_install() {
  53         einstalldocs
  54         dobin ethq
  55 }