sys-apps/apmd/apmd-3.2.2_p14.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit eutils multilib toolchain-funcs
   6
   7 MY_PV=${PV%_p*}
   8 MY_P=${PN}_${MY_PV}
   9 PATCHV=${PV#*_p}
  10
  11 DESCRIPTION="Advanced Power Management Daemon"
  12 HOMEPAGE="http://packages.qa.debian.org/a/apmd.html"
  13 SRC_URI="mirror://debian/pool/main/a/apmd/${MY_P}.orig.tar.gz
  14         mirror://debian/pool/main/a/apmd/${MY_P}-${PATCHV}.diff.gz"
  15
  16 LICENSE="GPL-2"
  17 SLOT="0"
  18 KEYWORDS="amd64 arm ppc ppc64 x86"
  19 IUSE="nls X"
  20
  21 RDEPEND=">=sys-apps/debianutils-1.16
  22         >=sys-power/powermgmt-base-1.31
  23         X? ( x11-libs/libX11
  24                 x11-libs/libXaw
  25                 x11-libs/libXmu
  26                 x11-libs/libSM
  27                 x11-libs/libICE
  28                 x11-libs/libXt
  29                 x11-libs/libXext )"
  30 DEPEND="${RDEPEND}
  31         sys-devel/libtool
  32         virtual/os-headers"
  33
  34 S=${WORKDIR}/${PN}-${MY_PV}.orig
  35
  36 src_prepare() {
  37         epatch "${WORKDIR}"/${MY_P}-${PATCHV}.diff
  38
  39         if ! use X; then
  40                 sed -i \
  41                         -e 's:\(EXES=.*\)xapm:\1:' \
  42                         -e 's:\(.*\)\$(LT_INSTALL).*xapm.*$:\1echo:' \
  43                         Makefile || die
  44         fi
  45
  46         # use system headers and skip on_ac_power
  47         rm -f on_ac_power*
  48
  49         sed -i \
  50                 -e '/on_ac_power/d' \
  51                 -e 's:-I/usr/src/linux/include -I/usr/X11R6/include::' \
  52                 -e 's:-L/usr/X11R6/lib::' \
  53                 Makefile || die
  54 }
  55
  56 src_compile() {
  57         emake CC=$(tc-getCC) CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
  58 }
  59
  60 src_install() {
  61         dodir /usr/sbin
  62         emake DESTDIR="${D}" PREFIX=/usr LIBDIR=/usr/$(get_libdir) install
  63
  64         keepdir /etc/apm/{event.d,suspend.d,resume.d,other.d,scripts.d}
  65         exeinto /etc/apm
  66         doexe debian/apmd_proxy
  67         dodoc AUTHORS {,apmsleep.}README debian/{changelog,README.Debian}
  68
  69         doman *.{1,8}
  70
  71         # note: apmd_proxy.conf is currently disabled and not used, thus
  72         # not installed - liquidx (01 Mar 2004)
  73
  74         newconfd "${FILESDIR}"/apmd.confd apmd
  75         newinitd "${FILESDIR}"/apmd.rc6 apmd
  76
  77         use nls || rm -rf "${D}"/usr/share/man/fr
  78 }