skel.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 # NOTE: The comments in this file are for instruction and documentation.
   5 # They're not meant to appear with your final, production ebuild.  Please
   6 # remember to remove them before submitting or committing your ebuild.  That
   7 # doesn't mean you can't add your own comments though.
   8
   9 # The EAPI variable tells the ebuild format in use.
  10 # It is suggested that you use the latest EAPI approved by the Council.
  11 # The PMS contains specifications for all EAPIs. Eclasses will test for this
  12 # variable if they need to use features that are not universal in all EAPIs.
  13 # If an eclass doesn't support latest EAPI, use the previous EAPI instead.
  14 EAPI=7
  15
  16
  17 # inherit lists eclasses to inherit functions from. For example, an ebuild
  18 # that needs the eautoreconf function from autotools.eclass won't work
  19 # without the following line:
  20 #inherit autotools
  21 #
  22 # Eclasses tend to list descriptions of how to use their functions properly.
  23 # Take a look at the eclass/ directory for more examples.
  24
  25 # Short one-line description of this package.
  26 DESCRIPTION="This is a sample skeleton ebuild file"
  27
  28 # Homepage, not used by Portage directly but handy for developer reference
  29 HOMEPAGE="https://foo.example.org/"
  30
  31 # Point to any required sources; these will be automatically downloaded by
  32 # Portage.
  33 SRC_URI="ftp://foo.example.org/${P}.tar.gz"
  34
  35
  36 # License of the package.  This must match the name of file(s) in the
  37 # licenses/ directory.  For complex license combination see the developer
  38 # docs on gentoo.org for details.
  39 LICENSE=""
  40
  41 # The SLOT variable is used to tell Portage if it's OK to keep multiple
  42 # versions of the same package installed at the same time.  For example,
  43 # if we have a libfoo-1.2.2 and libfoo-1.3.2 (which is not compatible
  44 # with 1.2.2), it would be optimal to instruct Portage to not remove
  45 # libfoo-1.2.2 if we decide to upgrade to libfoo-1.3.2.  To do this,
  46 # we specify SLOT="1.2" in libfoo-1.2.2 and SLOT="1.3" in libfoo-1.3.2.
  47 # emerge clean understands SLOTs, and will keep the most recent version
  48 # of each SLOT and remove everything else.
  49 # Note that normal applications should use SLOT="0" if possible, since
  50 # there should only be exactly one version installed at a time.
  51 # Do not use SLOT="", because the SLOT variable must not be empty.
  52 SLOT="0"
  53
  54 # Using KEYWORDS, we can record masking information *inside* an ebuild
  55 # instead of relying on an external package.mask file.  Right now, you
  56 # should set the KEYWORDS variable for every ebuild so that it contains
  57 # the names of all the architectures with which the ebuild works.
  58 # All of the official architectures can be found in the arch.list file
  59 # which is in the profiles/ directory.  Usually you should just set this
  60 # to "~amd64".  The ~ in front of the architecture indicates that the
  61 # package is new and should be considered unstable until testing proves
  62 # its stability.  So, if you've confirmed that your ebuild works on
  63 # amd64 and ppc, you'd specify:
  64 # KEYWORDS="~amd64 ~ppc"
  65 # Once packages go stable, the ~ prefix is removed.
  66 # For binary packages, use -* and then list the archs the bin package
  67 # exists for.  If the package was for an x86 binary package, then
  68 # KEYWORDS would be set like this: KEYWORDS="-* x86"
  69 # Do not use KEYWORDS="*"; this is not valid in an ebuild context.
  70 KEYWORDS="~amd64"
  71
  72 # Comprehensive list of any and all USE flags leveraged in the ebuild,
  73 # with some exceptions, e.g., ARCH specific flags like "amd64" or "ppc".
  74 # Not needed if the ebuild doesn't use any USE flags.
  75 IUSE="gnome X"
  76
  77 # A space delimited list of portage features to restrict. man 5 ebuild
  78 # for details.  Usually not needed.
  79 #RESTRICT="strip"
  80
  81
  82 # Run-time dependencies. Must be defined to whatever this depends on to run.
  83 # Example:
  84 #    ssl? ( >=dev-libs/openssl-1.0.2q:0= )
  85 #    >=dev-lang/perl-5.24.3-r1
  86 # It is advisable to use the >= syntax show above, to reflect what you
  87 # had installed on your system when you tested the package.  Then
  88 # other users hopefully won't be caught without the right version of
  89 # a dependency.
  90 #RDEPEND=""
  91
  92 # Build-time dependencies that need to be binary compatible with the system
  93 # being built (CHOST). These include libraries that we link against.
  94 # The below is valid if the same run-time depends are required to compile.
  95 #DEPEND="${RDEPEND}"
  96
  97 # Build-time dependencies that are executed during the emerge process, and
  98 # only need to be present in the native build system (CBUILD). Example:
  99 #BDEPEND="virtual/pkgconfig"
 100
 101
 102 # Source directory; the dir where the sources can be found (automatically
 103 # unpacked) inside ${WORKDIR}.  The default value for S is ${WORKDIR}/${P}
 104 # If you don't need to change it, leave the S= line out of the ebuild
 105 # to keep it tidy.
 106 #S="${WORKDIR}/${P}"
 107
 108
 109 # The following src_configure function is implemented as default by portage, so
 110 # you only need to call it if you need a different behaviour.
 111 #src_configure() {
 112         # Most open-source packages use GNU autoconf for configuration.
 113         # The default, quickest (and preferred) way of running configure is:
 114         #econf
 115         #
 116         # You could use something similar to the following lines to
 117         # configure your package before compilation.  The "|| die" portion
 118         # at the end will stop the build process if the command fails.
 119         # You should use this at the end of critical commands in the build
 120         # process.  (Hint: Most commands are critical, that is, the build
 121         # process should abort if they aren't successful.)
 122         #./configure \
 123         #       --host=${CHOST} \
 124         #       --prefix=/usr \
 125         #       --infodir=/usr/share/info \
 126         #       --mandir=/usr/share/man || die
 127         # Note the use of --infodir and --mandir, above. This is to make
 128         # this package FHS 2.2-compliant.  For more information, see
 129         #   https://wiki.linuxfoundation.org/lsb/fhs
 130 #}
 131
 132 # The following src_compile function is implemented as default by portage, so
 133 # you only need to call it, if you need different behaviour.
 134 #src_compile() {
 135         # emake is a script that calls the standard GNU make with parallel
 136         # building options for speedier builds (especially on SMP systems).
 137         # Try emake first.  It might not work for some packages, because
 138         # some makefiles have bugs related to parallelism, in these cases,
 139         # use emake -j1 to limit make to a single process.  The -j1 is a
 140         # visual clue to others that the makefiles have bugs that have been
 141         # worked around.
 142
 143         #emake
 144 #}
 145
 146 # The following src_install function is implemented as default by portage, so
 147 # you only need to call it, if you need different behaviour.
 148 #src_install() {
 149         # You must *personally verify* that this trick doesn't install
 150         # anything outside of DESTDIR; do this by reading and
 151         # understanding the install part of the Makefiles.
 152         # This is the preferred way to install.
 153         #emake DESTDIR="${D}" install
 154
 155         # When you hit a failure with emake, do not just use make. It is
 156         # better to fix the Makefiles to allow proper parallelization.
 157         # If you fail with that, use "emake -j1", it's still better than make.
 158
 159         # For Makefiles that don't make proper use of DESTDIR, setting
 160         # prefix is often an alternative.  However if you do this, then
 161         # you also need to specify mandir and infodir, since they were
 162         # passed to ./configure as absolute paths (overriding the prefix
 163         # setting).
 164         #emake \
 165         #       prefix="${D}"/usr \
 166         #       mandir="${D}"/usr/share/man \
 167         #       infodir="${D}"/usr/share/info \
 168         #       libdir="${D}"/usr/$(get_libdir) \
 169         #       install
 170         # Again, verify the Makefiles!  We don't want anything falling
 171         # outside of ${D}.
 172 #}