sci-misc/mendeleydesktop/mendeleydesktop-1.19.4.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
   6
   7 inherit desktop python-single-r1 xdg
   8
   9 MY_P_AMD64="${P}-linux-x86_64"
  10 MY_P_X86="${P}-linux-i486"
  11
  12 DESCRIPTION="Research management tool for desktop and web"
  13 HOMEPAGE="https://www.mendeley.com/"
  14 SRC_URI="
  15         amd64? ( ${MY_P_AMD64}.tar.bz2 )
  16         x86? ( ${MY_P_X86}.tar.bz2 )
  17         amd64-linux? ( ${MY_P_AMD64}.tar.bz2 )
  18         x86-linux? ( ${MY_P_X86}.tar.bz2 )"
  19
  20 LICENSE="Mendeley-terms"
  21 SLOT="0"
  22 KEYWORDS="~amd64 ~x86"
  23 IUSE=""
  24 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  25
  26 RESTRICT="bindist fetch"
  27
  28 DEPEND=""
  29 BDEPEND=""
  30 RDEPEND="${PYTHON_DEPS}
  31         dev-qt/qtcore:5
  32         dev-qt/qtdeclarative:5
  33         dev-qt/qtgui:5
  34         dev-qt/qtnetwork:5
  35         dev-qt/qtpositioning:5
  36         dev-qt/qtprintsupport:5
  37         dev-qt/qtsvg:5
  38         dev-qt/qtwebengine:5[widgets]
  39         dev-qt/qtwebkit:5
  40         dev-qt/qtxml:5
  41         sys-libs/zlib
  42         virtual/opengl
  43         x11-libs/libX11
  44 "
  45
  46 QA_PREBUILT="/opt/mendeleydesktop/.*"
  47
  48 PATCHES=(
  49         "${FILESDIR}"/${PN}-1.17.8-libdir.patch
  50         "${FILESDIR}"/${PN}-1.17.8-qt5plugins.patch
  51         "${FILESDIR}"/${PN}-1.17.8-unix-distro-build.patch
  52 )
  53
  54 pkg_nofetch() {
  55         elog "Please download ${A} from:"
  56         elog "http://www.mendeley.com/download-mendeley-desktop/"
  57         elog "and move it to your DISTDIR directory."
  58 }
  59
  60 src_unpack() {
  61         unpack ${A}
  62
  63         cd "${WORKDIR}" || die
  64
  65         if use amd64 || use amd64-linux ; then
  66                 mv -f "${MY_P_AMD64}" "${P}" || die
  67         else
  68                 mv -f "${MY_P_X86}" "${P}" || die
  69         fi
  70 }
  71
  72 src_prepare() {
  73         xdg_src_prepare
  74
  75         # remove bundled Qt libraries
  76         rm -r lib/mendeleydesktop/plugins \
  77                 || die "failed to remove plugin directory"
  78         rm -r lib/qt || die
  79
  80         # fix qt library path
  81         sed -e "s:/usr/lib/qt5/plugins:${EROOT}/usr/$(get_libdir)/qt5/plugins:g" \
  82                 -i bin/mendeleydesktop || die
  83
  84         # fix library paths
  85         sed -e "s:lib/mendeleydesktop:$(get_libdir)/mendeleydesktop:g" \
  86                 -e "s:MENDELEY_BASE'] + \"/lib/\":MENDELEY_BASE'] + \"/$(get_libdir)/\":g" \
  87                 -i bin/mendeleydesktop || die
  88 }
  89
  90 src_install() {
  91         # install menu
  92         domenu share/applications/${PN}.desktop
  93
  94         # install application icons
  95         insinto /usr/share/icons
  96         doins -r share/icons/hicolor
  97
  98         # install default icon
  99         insinto /usr/share/pixmaps
 100         doins share/icons/hicolor/48x48/apps/${PN}.png
 101
 102         # install documentation, but no license file
 103         dodoc share/doc/${PN}/Readme.txt
 104
 105         # install binary
 106         python_fix_shebang bin/${PN}
 107         into /opt/${PN}
 108         dobin bin/*
 109
 110         # install libraries
 111         dolib.so lib/lib*.so*
 112
 113         # remove qtconf and qt-5.10 workaround
 114         rm lib/mendeleydesktop/libexec/qt.conf
 115         rm "lib/mendeleydesktop/libexec/QtWebEngineProcess --type=zygote --lang=en-US"
 116
 117         # install programs
 118         exeinto /opt/mendeleydesktop/$(get_libdir)/mendeleydesktop/libexec
 119         doexe lib/mendeleydesktop/libexec/*
 120
 121         # install shared files
 122         insinto /opt/${PN}/share
 123         doins -r share/mendeleydesktop
 124
 125         # symlink launch script
 126         dosym ../mendeleydesktop/bin/mendeleydesktop /opt/bin/mendeleydesktop
 127 }