sci-misc/boinc/boinc-7.6.33-r3.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 WX_GTK_VER=3.0
   8
   9 inherit autotools eutils linux-info systemd user versionator wxwidgets
  10
  11 MY_PV=$(get_version_component_range 1-2)
  12
  13 DESCRIPTION="The Berkeley Open Infrastructure for Network Computing"
  14 HOMEPAGE="http://boinc.ssl.berkeley.edu/"
  15 SRC_URI="https://github.com/BOINC/boinc/archive/client_release/${MY_PV}/${PV}.tar.gz -> ${P}.tar.gz
  16         X? ( http://boinc.berkeley.edu/logo/boinc_glossy2_512_F.tif -> ${PN}.tif )"
  17 RESTRICT="mirror"
  18
  19 LICENSE="LGPL-2.1"
  20 SLOT="0"
  21 KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
  22 IUSE="X cuda curl_ssl_libressl +curl_ssl_openssl static-libs"
  23
  24 REQUIRED_USE="^^ ( curl_ssl_libressl curl_ssl_openssl ) "
  25
  26 # libcurl must not be using an ssl backend boinc does not support.
  27 # If the libcurl ssl backend changes, boinc should be recompiled.
  28 RDEPEND="
  29         !sci-misc/boinc-bin
  30         !app-admin/quickswitch
  31         >=app-misc/ca-certificates-20080809
  32         net-misc/curl[-curl_ssl_gnutls(-),curl_ssl_libressl(-)=,-curl_ssl_nss(-),curl_ssl_openssl(-)=,-curl_ssl_axtls(-),-curl_ssl_cyassl(-),-curl_ssl_polarssl(-)]
  33         sys-apps/util-linux
  34         sys-libs/zlib
  35         cuda? (
  36                 >=dev-util/nvidia-cuda-toolkit-2.1
  37                 >=x11-drivers/nvidia-drivers-180.22
  38         )
  39         X? (
  40                 dev-db/sqlite:3
  41                 media-libs/freeglut
  42                 sys-libs/glibc:2.2
  43                 virtual/jpeg:0=
  44                 x11-libs/gtk+:2
  45                 >=x11-libs/libnotify-0.7
  46                 x11-libs/wxGTK:${WX_GTK_VER}[X,opengl,webkit]
  47         )
  48 "
  49 DEPEND="${RDEPEND}
  50         sys-devel/gettext
  51         app-text/docbook-xml-dtd:4.4
  52         app-text/docbook2X
  53         X? ( virtual/imagemagick-tools[png,tiff] )
  54 "
  55
  56 PATCHES=(
  57         # >=x11-libs/wxGTK-3.0.2.0-r3 has webview removed, bug 587462
  58         "${FILESDIR}"/fix_webview.patch
  59 )
  60
  61 S="${WORKDIR}/${PN}-client_release-${MY_PV}-${PV}"
  62
  63 pkg_setup() {
  64         # Bug 578750
  65         if use kernel_linux; then
  66                 linux-info_pkg_setup
  67                 if ! linux_config_exists; then
  68                         ewarn "Can't check the linux kernel configuration."
  69                         ewarn "You might be missing vsyscall support."
  70                 elif kernel_is -ge 4 4 \
  71                     && linux_chkconfig_present LEGACY_VSYSCALL_NONE; then
  72                         ewarn "You do not have vsyscall emulation enabled."
  73                         ewarn "This will prevent some boinc projects from running."
  74                         ewarn "Please enable vsyscall emulation:"
  75                         ewarn "    CONFIG_LEGACY_VSYSCALL_EMULATE=y"
  76                         ewarn "in /usr/src/linux/.config, to be found at"
  77                         ewarn "    Processor type and features --->"
  78                         ewarn "        vsyscall table for legacy applications (None) --->"
  79                         ewarn "            (X) Emulate"
  80                         ewarn "Alternatively, you can enable CONFIG_LEGACY_VSYSCALL_NATIVE."
  81                         ewarn "However, this has security implications and is not recommended."
  82                 fi
  83         fi
  84 }
  85
  86 src_prepare() {
  87         default
  88
  89         # prevent bad changes in compile flags, bug 286701
  90         sed -i -e "s:BOINC_SET_COMPILE_FLAGS::" configure.ac || die "sed failed"
  91
  92         eautoreconf
  93
  94         use X && need-wxwidgets unicode
  95 }
  96
  97 src_configure() {
  98         econf --disable-server \
  99                 --enable-client \
 100                 --enable-dynamic-client-linkage \
 101                 --disable-static \
 102                 --enable-unicode \
 103                 --with-ssl \
 104                 $(use_with X x) \
 105                 $(use_enable X manager) \
 106                 $(usex X --with-wx-config="${WX_CONFIG}" --without-wxdir)
 107 }
 108
 109 src_install() {
 110         default
 111
 112         keepdir /var/lib/${PN}
 113
 114         if use X; then
 115                 # Create new icons. bug 593362
 116                 local s SIZES=(16 22 24 32 36 48 64 72 96 128 192 256)
 117                 for s in "${SIZES[@]}"; do
 118                         convert "${DISTDIR}"/${PN}.tif -resize ${s}x${s} "${WORKDIR}"/boinc_${s}.png || die
 119                         newicon -s $s "${WORKDIR}"/boinc_${s}.png boinc.png
 120                 done
 121                 make_desktop_entry boincmgr "${PN}" "${PN}" "Math;Science" "Path=/var/lib/${PN}"
 122
 123                 # Rename the desktop file to boincmgr.desktop to (hot)fix bug 599910
 124                 mv "${ED%/}"/usr/share/applications/boincmgr{-${PN},}.desktop || \
 125                         die "Failed to rename desktop file"
 126         fi
 127
 128         # cleanup cruft
 129         rm -rf "${ED%/}"/etc || die "rm failed"
 130
 131         newinitd "${FILESDIR}"/${PN}.init ${PN}
 132         newconfd "${FILESDIR}"/${PN}.conf ${PN}
 133         systemd_dounit "${FILESDIR}"/${PN}.service
 134 }
 135
 136 pkg_preinst() {
 137         enewgroup ${PN}
 138         # note this works only for first install so we have to
 139         # elog user about the need of being in video group
 140         local groups="${PN}"
 141         if use cuda; then
 142                 groups+=",video"
 143         fi
 144         enewuser ${PN} -1 -1 /var/lib/${PN} "${groups}"
 145 }
 146
 147 pkg_postinst() {
 148         elog
 149         elog "You are using the source compiled version of boinc."
 150         use X && elog "The graphical manager can be found at /usr/bin/boincmgr"
 151         elog
 152         elog "You need to attach to a project to do anything useful with boinc."
 153         elog "You can do this by running /etc/init.d/boinc attach"
 154         elog "The howto for configuration is located at:"
 155         elog "http://boinc.berkeley.edu/wiki/Anonymous_platform"
 156         elog
 157         # Add warning about the new password for the client, bug 121896.
 158         if use X; then
 159                 elog "If you need to use the graphical manager the password is in:"
 160                 elog "/var/lib/boinc/gui_rpc_auth.cfg"
 161                 elog "Where /var/lib/ is default RUNTIMEDIR, that can be changed in:"
 162                 elog "/etc/conf.d/boinc"
 163                 elog "You should change this password to something more memorable (can be even blank)."
 164                 elog "Remember to launch init script before using manager. Or changing the password."
 165                 elog
 166         fi
 167         if use cuda; then
 168                 elog "To be able to use CUDA you should add boinc user to video group."
 169                 elog "Run as root:"
 170                 elog "gpasswd -a boinc video"
 171         fi
 172 }