sci-mathematics/jags/jags-3.4.0.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit autotools-utils toolchain-funcs
   7
   8 MYP="JAGS-${PV}"
   9
  10 DESCRIPTION="Just Another Gibbs Sampler for Bayesian MCMC simulation"
  11 HOMEPAGE="http://mcmc-jags.sourceforge.net/"
  12 SRC_URI="mirror://sourceforge/project/mcmc-jags/JAGS/3.x/Source/${MYP}.tar.gz"
  13 LICENSE="GPL-2"
  14 IUSE="doc"
  15
  16 SLOT="0"
  17 KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
  18
  19 RDEPEND="
  20         virtual/blas
  21         virtual/lapack"
  22 DEPEND="${RDEPEND}
  23         virtual/pkgconfig
  24         doc? (
  25                 virtual/latex-base
  26                 dev-texlive/texlive-latexextra
  27                 )"
  28
  29 S="${WORKDIR}/${MYP}"
  30
  31 src_configure() {
  32         local myeconfargs=(
  33                 --with-blas="$($(tc-getPKG_CONFIG) --libs blas)"
  34                 --with-lapack="$($(tc-getPKG_CONFIG) --libs lapack)"
  35         )
  36         autotools-utils_src_configure
  37 }
  38
  39 src_compile() {
  40         autotools-utils_src_compile all $(use doc && echo docs)
  41 }
  42
  43 src_install() {
  44         autotools-utils_src_install
  45         use doc && dodoc "${BUILD_DIR}"/doc/manual/*.pdf
  46 }