sci-mathematics/euler/euler-1.61.0.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 AUTOTOOLS_AUTORECONF=1
   7 AUTOTOOLS_IN_SOURCE_BUILD=1
   8
   9 inherit autotools-utils
  10
  11 DESCRIPTION="Mathematical programming environment"
  12 HOMEPAGE="http://euler.sourceforge.net/"
  13 SRC_URI="mirror://sourceforge/euler/${P}.tgz"
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="amd64 ppc -sparc x86 ~amd64-linux ~x86-linux"
  17 IUSE=""
  18
  19 DEPEND="x11-libs/gtk+:2
  20         virtual/pkgconfig"
  21
  22 RDEPEND="x11-libs/gtk+:2
  23         x11-misc/xdg-utils"
  24
  25 PATCHES=(
  26         "${FILESDIR}"/configure-gentoo.patch
  27         "${FILESDIR}"/command-gcc4-gentoo.patch
  28         "${FILESDIR}"/${PN}-glibc-2.4-gentoo.patch
  29         "${FILESDIR}"/${PN}-xdg.patch
  30         "${FILESDIR}"/${PN}-fortify.patch
  31 )
  32
  33 src_prepare() {
  34         # gentoo specific stuff
  35         sed -i -e '/COPYING/d' -e '/INSTALL/d' Makefile.am || die
  36         sed -i \
  37                 -e "s:doc/euler:doc/${PF}:g" \
  38                 Makefile.am docs/Makefile.am \
  39                 docs/*/Makefile.am docs/*/images/Makefile.am src/main.c  \
  40                 || die "sed for docs failed"
  41         autotools-utils_src_prepare
  42 }