sci-mathematics/dataplot/dataplot-20131220.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils fortran-2 toolchain-funcs autotools
   7
   8 #     YEAR         MONTH    DAY
   9 MY_PV=${PV:0:4}_${PV:4:2}_${PV:6:2}
  10 MY_P=dpsrc_${MY_PV}
  11 # MY_PV_AUX usually ${MY_PV}
  12 MY_PV_AUX=2009_07_15
  13 MY_P_AUX=dplib.${MY_PV_AUX}
  14
  15 DESCRIPTION="Program for scientific visualization and statistical analyis"
  16 HOMEPAGE="https://www.itl.nist.gov/div898/software/dataplot/"
  17 SRC_URI="
  18         ftp://ftp.nist.gov/pub/dataplot/unix/${MY_P}.tar.gz
  19         ftp://ftp.nist.gov/pub/dataplot/unix/${MY_P_AUX}.tar.gz"
  20
  21 SLOT="0"
  22 LICENSE="public-domain"
  23 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  24 IUSE="examples gd opengl X"
  25
  26 REQUIRED_USE="opengl? ( X )"
  27
  28 COMMON_DEPEND="
  29         media-libs/plotutils
  30         opengl? ( virtual/opengl )
  31         gd? ( media-libs/gd[png,jpeg] )"
  32 DEPEND="${COMMON_DEPEND}
  33         virtual/pkgconfig"
  34 RDEPEND="${COMMON_DEPEND}
  35         X? ( x11-misc/xdg-utils )"
  36
  37 S="${WORKDIR}/${MY_P}"
  38 S_AUX="${WORKDIR}/${MY_P_AUX}"
  39
  40 PATCHES=( "${FILESDIR}"/${PN}-20090821-opengl.patch )
  41
  42 src_unpack() {
  43         # unpacking and renaming because
  44         # upstream does not use directories
  45         mkdir "${S_AUX}" || die
  46         pushd "${S_AUX}" > /dev/null || die
  47         unpack ${MY_P_AUX}.tar.gz
  48         popd > /dev/null || die
  49         mkdir ${MY_P} || die
  50         cd "${S}" || die
  51         unpack ${MY_P}.tar.gz
  52 }
  53
  54 src_prepare() {
  55         default
  56         cp "${FILESDIR}"/Makefile.am.${PV} Makefile.am || die
  57         cp "${FILESDIR}"/configure.ac.${PV} configure.ac || die
  58         sed -e "s:IHOST1='SUN':IHOST1='@HOST@:" \
  59                 -e "s:/usr/local/lib:@datadir@:g" \
  60                 dp1_linux.f > dp1_linux.f.in || die
  61         sed -e "s/(MAXOBV=.*)/(MAXOBV=@MAXOBV@)/" \
  62                 -e "s:/usr/local/lib:@datadir@:g" \
  63                 DPCOPA.INC > DPCOPA.INC.in || die
  64
  65         eautoreconf
  66 }
  67
  68 src_configure() {
  69         econf \
  70                 $(use_enable gd) \
  71                 $(use_enable opengl gl) \
  72                 $(use_enable X)
  73 }
  74
  75 src_install() {
  76         default
  77
  78         if use examples; then
  79                 insinto /usr/share/doc/${PF}/examples
  80                 doins -r "${S_AUX}"/data/*
  81         fi
  82         insinto /usr/share/dataplot
  83         doins "${S_AUX}"/dp{mes,sys,log}f.tex
  84         doenvd "${FILESDIR}"/90${PN}
  85 }