sci-mathematics/dataplot/dataplot-20090821.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils fortran-2 toolchain-funcs autotools
   8
   9 #     YEAR         MONTH    DAY
  10 MY_PV=${PV:0:4}_${PV:4:2}_${PV:6:2}
  11 MY_P=dpsrc_${MY_PV}
  12 # MY_PV_AUX usually ${MY_PV}
  13 MY_PV_AUX=2009_07_15
  14 MY_P_AUX=dplib.${MY_PV_AUX}
  15
  16 DESCRIPTION="Program for scientific visualization and statistical analyis"
  17 HOMEPAGE="http://www.itl.nist.gov/div898/software/dataplot/"
  18 SRC_URI="
  19         ftp://ftp.nist.gov/pub/dataplot/unix/${MY_P}.tar.gz
  20         ftp://ftp.nist.gov/pub/dataplot/unix/${MY_P_AUX}.tar.gz"
  21
  22 SLOT="0"
  23 LICENSE="public-domain"
  24 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  25 IUSE="examples gd opengl X"
  26
  27 COMMON_DEPEND="
  28         media-libs/plotutils
  29         opengl? ( virtual/opengl )
  30         gd? ( media-libs/gd[png,jpeg] )"
  31 DEPEND="${COMMON_DEPEND}
  32         virtual/pkgconfig"
  33 RDEPEND="${COMMON_DEPEND}
  34         X? ( x11-misc/xdg-utils )"
  35
  36 S="${WORKDIR}/${MY_P}"
  37 S_AUX="${WORKDIR}/${MY_P_AUX}"
  38
  39 src_unpack() {
  40         # unpacking and renaming because
  41         # upstream does not use directories
  42         mkdir "${S_AUX}" || die
  43         pushd "${S_AUX}" > /dev/null || die
  44         unpack ${MY_P_AUX}.tar.gz
  45         popd > /dev/null || die
  46         mkdir ${MY_P} || die
  47         cd "${S}" || die
  48         unpack ${MY_P}.tar.gz
  49 }
  50
  51 src_prepare() {
  52         epatch "${FILESDIR}"/${P}-opengl.patch
  53         cp "${FILESDIR}"/Makefile.am.${PV} Makefile.am || die
  54         cp "${FILESDIR}"/configure.ac.${PV} configure.ac || die
  55         sed -e "s:IHOST1='SUN':IHOST1='@HOST@:" \
  56                 -e "s:/usr/local/lib:@datadir@:g" \
  57                 dp1_linux.f > dp1_linux.f.in || die
  58         sed -e "s/(MAXOBV=.*)/(MAXOBV=@MAXOBV@)/" \
  59                 -e "s:/usr/local/lib:@datadir@:g" \
  60                 DPCOPA.INC > DPCOPA.INC.in || die
  61         eautoreconf
  62 }
  63
  64 src_configure() {
  65         econf \
  66                 $(use_enable gd) \
  67                 $(use_enable opengl gl) \
  68                 $(use_enable X)
  69 }
  70
  71 src_install() {
  72         default
  73
  74         if use examples; then
  75                 insinto /usr/share/doc/${PF}/examples
  76                 doins -r "${S_AUX}"/data/*
  77         fi
  78         insinto /usr/share/dataplot
  79         doins "${S_AUX}"/dp{mes,sys,log}f.tex
  80         doenvd "${FILESDIR}"/90${PN}
  81 }