sci-libs/rtabmap/rtabmap-0.17.1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 SCM=""
   7 if [ "${PV#9999}" != "${PV}" ] ; then
   8         SCM="git-r3"
   9         EGIT_REPO_URI="https://github.com/introlab/rtabmap"
  10 fi
  11
  12 inherit ${SCM} cmake-utils multilib
  13
  14 if [ "${PV#9999}" != "${PV}" ] ; then
  15         KEYWORDS=""
  16         SRC_URI=""
  17 else
  18         KEYWORDS="~amd64"
  19         SRC_URI="https://github.com/introlab/rtabmap/archive/${PV}-melodic.tar.gz -> ${P}.tar.gz"
  20         S="${WORKDIR}/${P}-melodic"
  21 fi
  22
  23 DESCRIPTION="Real-Time Appearance-Based Mapping (RGB-D Graph SLAM)"
  24 HOMEPAGE="http://introlab.github.io/rtabmap/"
  25 LICENSE="BSD"
  26 SLOT="0"
  27 IUSE="examples ieee1394 openni2 qt5"
  28
  29 RDEPEND="
  30         media-libs/opencv:=[qt5(-)?]
  31         sci-libs/pcl:=[openni,vtk,qt5(-)?]
  32         sci-libs/vtk:=[qt5(-)?]
  33         sys-libs/zlib
  34         sci-libs/octomap:=
  35         dev-libs/boost:=
  36         ieee1394? ( media-libs/libdc1394 )
  37         openni2? ( dev-libs/OpenNI2 )
  38         qt5? (
  39                 dev-qt/qtwidgets:5
  40                 dev-qt/qtcore:5
  41                 dev-qt/qtgui:5
  42                 dev-qt/qtsvg:5
  43         )
  44 "
  45 DEPEND="${RDEPEND}
  46         virtual/pkgconfig"
  47
  48 src_configure() {
  49         local mycmakeargs=(
  50                 "-DWITH_QT=$(usex qt5 ON OFF)"
  51                 "-DWITH_DC1394=$(usex ieee1394 ON OFF)"
  52                 "-DWITH_OPENNI2=$(usex openni2 ON OFF)"
  53                 "-DBUILD_EXAMPLES=$(usex examples ON OFF)"
  54         )
  55         cmake-utils_src_configure
  56 }
  57
  58 src_install() {
  59         cmake-utils_src_install
  60         # Needed since we force ros crawling to be done only in
  61         # /usr/share/ros_packages/
  62         insinto /usr/share/ros_packages/${PN}
  63         doins "${ED}/usr/share/${PN}/package.xml"
  64 }