sci-libs/netcdf/netcdf-4.6.1-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils ltprune
   7
   8 DESCRIPTION="Scientific library and interface for array oriented data access"
   9 HOMEPAGE="https://www.unidata.ucar.edu/software/netcdf/"
  10 SRC_URI="https://github.com/Unidata/netcdf-c/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="UCAR-Unidata"
  13 SLOT="0/13"
  14 KEYWORDS="amd64 ~arm ~ia64 ~ppc ~ppc64 x86 ~amd64-linux ~x86-linux"
  15 IUSE="+dap examples hdf +hdf5 mpi static-libs szip test tools"
  16 RESTRICT="!test? ( test )"
  17
  18 RDEPEND="
  19         dap? ( net-misc/curl:0= )
  20         hdf? ( sci-libs/hdf:0= sci-libs/hdf5:0= )
  21         hdf5? ( sci-libs/hdf5:0=[hl(+),mpi=,szip=,zlib] )"
  22 DEPEND="${RDEPEND}"
  23 # doc generation is missing many doxygen files in tar ball
  24 #       doc? ( app-doc/doxygen[dot] )"
  25
  26 REQUIRED_USE="test? ( tools ) szip? ( hdf5 ) mpi? ( hdf5 )"
  27
  28 S="${WORKDIR}/${PN}-c-${PV}"
  29
  30 src_configure() {
  31         local myconf
  32         if use mpi; then
  33                 export CC=mpicc
  34         fi
  35         econf "${myconf}" \
  36                 --disable-examples \
  37                 --disable-dap-remote-tests \
  38                 $(use_enable dap) \
  39                 $(use_enable hdf hdf4) \
  40                 $(use_enable hdf5 netcdf-4) \
  41                 $(use_enable static-libs static) \
  42                 $(use_enable tools utilities)
  43 }
  44
  45 src_test() {
  46         # fails parallel tests: bug #621486
  47         emake check -j1
  48 }
  49
  50 src_install() {
  51         default
  52         use examples && dodoc -r examples
  53         prune_libtool_files
  54 }