sci-libs/libgeodecomp/libgeodecomp-0.5.0_pre20200420.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake cuda virtualx
   7
   8 MY_COMMIT="69c5573ac7b2b654d649e8902fad73b05bf33644"
   9
  10 DESCRIPTION="An auto-parallelizing library to speed up computer simulations"
  11 HOMEPAGE="
  12         http://www.libgeodecomp.org
  13         https://github.com/STEllAR-GROUP/libgeodecomp"
  14 SRC_URI="https://github.com/STEllAR-GROUP/libgeodecomp/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
  15
  16 SLOT="0"
  17 LICENSE="Boost-1.0"
  18 KEYWORDS="~amd64 ~ppc ~x86"
  19 IUSE="cuda doc hpx mpi opencl opencv qt5 silo"
  20
  21 BDEPEND="
  22         doc? (
  23                 app-doc/doxygen
  24                 app-text/texlive
  25                 media-gfx/graphviz
  26         )"
  27 RDEPEND="dev-libs/boost"
  28 DEPEND="${RDEPEND}
  29         ~dev-libs/libflatarray-0.4.0_pre20200314
  30         cuda? ( dev-util/nvidia-cuda-toolkit )
  31         hpx? ( sys-cluster/hpx )
  32         mpi? ( virtual/mpi )
  33         opencl? ( virtual/opencl )
  34         opencv? ( media-libs/opencv )
  35         qt5? (
  36                 dev-qt/qtcore:5
  37                 dev-qt/qtgui:5
  38                 dev-qt/qtopengl:5
  39                 dev-qt/qtwidgets:5
  40         )
  41         silo? ( sci-libs/silo )"
  42
  43 S="${WORKDIR}/libgeodecomp-${MY_COMMIT}"
  44
  45 PATCHES=( "${FILESDIR}/${P}-mpi.patch" )
  46
  47 DOCS=( README )
  48
  49 src_prepare() {
  50         cmake_src_prepare
  51         use cuda && cuda_src_prepare
  52 }
  53
  54 src_configure() {
  55         local mycmakeargs=(
  56                 -DWITH_CUDA=$(usex cuda)
  57                 -DWITH_HPX=$(usex hpx)
  58                 -DWITH_MPI=$(usex mpi)
  59                 -DWITH_OPENCL=$(usex opencl)
  60                 -DWITH_OPENCV=$(usex opencv)
  61                 -DWITH_QT5=$(usex qt5)
  62                 -DWITH_SCOTCH=false
  63                 -DWITH_SILO=$(usex silo)
  64                 -DWITH_TYPEMAPS=false
  65                 -DWITH_VISIT=false
  66         )
  67         cmake_src_configure
  68 }
  69
  70 src_compile() {
  71         cmake_src_compile
  72         use doc && cmake_build doc
  73 }
  74
  75 src_install() {
  76         use doc && local HTML_DOCS=( doc/html/* )
  77         cmake_src_install
  78 }
  79
  80 src_test() {
  81         virtx cmake_build check
  82 }