sci-libs/indilib/indilib-1.8.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake udev
   7
   8 DESCRIPTION="INDI Astronomical Control Protocol library"
   9 HOMEPAGE="https://www.indilib.org/"
  10 SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
  13 SLOT="0/1"
  14 KEYWORDS="amd64 ~ppc ~ppc64 x86"
  15 IUSE="ogg test websocket"
  16
  17 RDEPEND="
  18         net-misc/curl
  19         sci-libs/cfitsio:=
  20         sci-libs/fftw:3.0=
  21         sci-libs/gsl:=
  22         sci-libs/libnova:=
  23         sys-libs/zlib
  24         virtual/jpeg:0
  25         virtual/libusb:0
  26         ogg? (
  27                 media-libs/libogg
  28                 media-libs/libtheora
  29         )
  30         websocket? ( dev-libs/boost:= )
  31 "
  32 DEPEND="${RDEPEND}
  33         kernel_linux? ( sys-kernel/linux-headers )
  34         test? ( >=dev-cpp/gtest-1.8.0 )
  35         websocket? ( dev-cpp/websocketpp )
  36 "
  37
  38 RESTRICT="!test? ( test )"
  39
  40 S="${WORKDIR}/${P/lib/}"
  41
  42 src_configure() {
  43         local mycmakeargs=(
  44                 -DINDI_BUILD_QT5_CLIENT=OFF
  45                 -DINDI_BUILD_UNITTESTS=$(usex test)
  46                 -DUDEVRULES_INSTALL_DIR="$(get_udevdir)"/rules.d
  47                 $(cmake_use_find_package ogg OggTheora)
  48                 -DINDI_BUILD_WEBSOCKET=$(usex websocket)
  49         )
  50
  51         cmake_src_configure
  52 }
  53
  54 src_test() {
  55         BUILD_DIR="${BUILD_DIR}"/test cmake_src_test
  56 }