sci-libs/gsl/gsl-1.16.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils flag-o-matic autotools toolchain-funcs
   8
   9 DESCRIPTION="The GNU Scientific Library"
  10 HOMEPAGE="https://www.gnu.org/software/gsl/"
  11 SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
  12
  13 LICENSE="GPL-3"
  14 SLOT="0"
  15 KEYWORDS="alpha amd64 arm hppa ~ia64 ~mips ppc ~ppc64 ~s390 ~sh ~sparc x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x86-macos ~sparc-solaris ~x86-solaris"
  16 IUSE="cblas-external static-libs"
  17
  18 RDEPEND="cblas-external? ( virtual/cblas )"
  19 DEPEND="${RDEPEND}
  20         app-eselect/eselect-cblas
  21         virtual/pkgconfig"
  22
  23 DOCS=( AUTHORS BUGS ChangeLog NEWS README THANKS TODO )
  24
  25 pkg_pretend() {
  26         # prevent to use external cblas from a previously installed gsl
  27         local current_lib
  28         if use cblas-external; then
  29                 current_lib=$(eselect cblas show | cut -d' ' -f2)
  30                 if [[ ${current_lib} == gsl ]]; then
  31                         ewarn "USE flag cblas-external is set: linking gsl with an external cblas."
  32                         ewarn "However the current selected external cblas is gsl."
  33                         ewarn "Please install and/or eselect another cblas"
  34                         die "Circular gsl dependency"
  35                 fi
  36         fi
  37 }
  38
  39 src_prepare() {
  40         ESELECT_PROF="gsl"
  41
  42         # bug 349005
  43         [[ $(tc-getCC)$ == *gcc* ]] && \
  44                 [[ $(tc-getCC)$ != *apple* ]] && \
  45                 [[ $(gcc-major-version)$(gcc-minor-version) -eq 44 ]] \
  46                 && filter-mfpmath sse
  47         filter-flags -ffast-math
  48
  49         epatch "${FILESDIR}"/${P}-cblas.patch
  50         eautoreconf
  51
  52         cp "${FILESDIR}"/eselect.cblas.gsl "${T}"/ || die
  53         sed -i -e "s:/usr:${EPREFIX}/usr:" "${T}"/eselect.cblas.gsl || die
  54         if [[ ${CHOST} == *-darwin* ]] ; then
  55                 sed -i -e 's/\.so\([\.0-9]\+\)\?/\1.dylib/g' \
  56                         "${T}"/eselect.cblas.gsl || die
  57         fi
  58 }
  59
  60 src_configure() {
  61         if use cblas-external; then
  62                 export CBLAS_LIBS="$($(tc-getPKG_CONFIG) --libs cblas)"
  63                 export CBLAS_CFLAGS="$($(tc-getPKG_CONFIG) --cflags cblas)"
  64         fi
  65         econf \
  66                 --enable-shared \
  67                 $(use_with cblas-external) \
  68                 $(use_enable static-libs static)
  69 }
  70
  71 src_test() {
  72         emake -j1 check
  73 }
  74
  75 src_install() {
  76         default
  77
  78         find "${ED}" -name '*.la' -exec rm -f {} + || die
  79
  80         # take care of pkgconfig file for cblas implementation.
  81         sed -e "s/@LIBDIR@/$(get_libdir)/" \
  82                 -e "s/@PV@/${PV}/" \
  83                 -e "/^prefix=/s:=:=${EPREFIX}:" \
  84                 -e "/^libdir=/s:=:=${EPREFIX}:" \
  85                 "${FILESDIR}"/cblas.pc.in > cblas.pc \
  86                 || die "sed cblas.pc failed"
  87         insinto /usr/$(get_libdir)/blas/gsl
  88         doins cblas.pc
  89         eselect cblas add $(get_libdir) "${T}"/eselect.cblas.gsl \
  90                 ${ESELECT_PROF}
  91 }
  92
  93 pkg_postinst() {
  94         local p=cblas
  95         local current_lib=$(eselect ${p} show | cut -d' ' -f2)
  96         if [[ ${current_lib} == ${ESELECT_PROF} || -z ${current_lib} ]]; then
  97                 # work around eselect bug #189942
  98                 local configfile="${EROOT}"/etc/env.d/${p}/$(get_libdir)/config
  99                 [[ -e ${configfile} ]] && rm -f ${configfile}
 100                 eselect ${p} set ${ESELECT_PROF}
 101                 elog "${p} has been eselected to ${ESELECT_PROF}"
 102         else
 103                 elog "Current eselected ${p} is ${current_lib}"
 104                 elog "To use ${p} ${ESELECT_PROF} implementation, you have to issue (as root):"
 105                 elog "\t eselect ${p} set ${ESELECT_PROF}"
 106         fi
 107 }