sci-libs/dsdp/dsdp-5.8-r3.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit multilib toolchain-funcs versionator
   7
   8 MY_P="${PN^^}${PV}"
   9
  10 DESCRIPTION="Software for interior-point for semidefinite programming"
  11 HOMEPAGE="http://www.mcs.anl.gov/hs/software/DSDP/"
  12 SRC_URI="http://www.mcs.anl.gov/hs/software/DSDP/${MY_P}.tar.gz"
  13
  14 LICENSE="BSD"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
  17 IUSE="doc examples"
  18
  19 RDEPEND="virtual/lapack"
  20 DEPEND="${RDEPEND}
  21         virtual/pkgconfig"
  22
  23 S="${WORKDIR}/${MY_P}"
  24
  25 PATCHES=(
  26         "${FILESDIR}"/${P}-readsdpa.patch
  27         "${FILESDIR}"/${P}-malloc.patch
  28         "${FILESDIR}"/${P}-gold.patch
  29 )
  30
  31 make_shared_lib() {
  32         local soname=$(basename "${1%.a}")$(get_libname $(get_major_version))
  33         einfo "Making ${soname}"
  34         ${2:-$(tc-getCC)} ${LDFLAGS}  \
  35                 -shared -Wl,-soname="${soname}" \
  36                 $([[ ${CHOST} == *-darwin* ]] && echo "-Wl,-install_name -Wl,${EPREFIX}/usr/$(get_libdir)/${soname}") \
  37                 -Wl,--whole-archive "${1}" -Wl,--no-whole-archive \
  38                 -o $(dirname "${1}")/"${soname}" \
  39                 -lm $($(tc-getPKG_CONFIG) --libs blas lapack) || return 1
  40 }
  41
  42 src_prepare() {
  43         default
  44         # to do proper parallel compilation
  45         while IFS="" read -d $'\0' -r file; do
  46                 sed -i -e 's:make :$(MAKE) :g' "${file}" || die
  47         done < <(find . -name Makefile -print0)
  48         sed -i -e 's:make clean:$(MAKE) clean:g' make.include || die
  49         sed -i \
  50                 -e "s|#\(DSDPROOT[[:space:]]*=\).*|\1${S}|" \
  51                 -e "s|\(CC[[:space:]]*=\).*|\1$(tc-getCC)|" \
  52                 -e "s|\(OPTFLAGS[[:space:]]*=\).*|\1${CFLAGS}|" \
  53                 -e "s|\(CLINKER[[:space:]]*=\).*|\1 \${CC} ${LDFLAGS}|" \
  54                 -e "s|\(LAPACKBLAS[[:space:]]*=\).*|\1 $($(tc-getPKG_CONFIG) --libs blas lapack)|" \
  55                 -e "s|\(^ARCH[[:space:]]*=\).*|\1$(tc-getAR) cr|" \
  56                 -e "s|\(^RANLIB[[:space:]]*=\).*|\1$(tc-getRANLIB)|" \
  57                 make.include || die
  58 }
  59
  60 src_compile() {
  61         emake OPTFLAGS="${CFLAGS} -fPIC" dsdplibrary
  62         make_shared_lib lib/lib${PN}.a || die "doing shared lib failed"
  63 }
  64
  65 src_test() {
  66         emake -j1 example test
  67 }
  68
  69 src_install() {
  70         dolib.so lib/lib${PN}$(get_libname $(get_major_version))
  71         dosym lib${PN}$(get_libname $(get_major_version)) \
  72                 /usr/$(get_libdir)/lib${PN}$(get_libname)
  73
  74         doheader include/*.h src/sdp/*.h
  75
  76         use doc && DOCS+=( docs/*.pdf )
  77         use examples && DOCS+=( examples/. )
  78         einstalldocs
  79 }