sci-libs/coinor-os/coinor-os-2.8.3.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit autotools-utils multilib flag-o-matic
   8
   9 MYPN=OS
  10
  11 DESCRIPTION="COIN-OR Optimization Services"
  12 HOMEPAGE="https://projects.coin-or.org/OS/"
  13 SRC_URI="http://www.coin-or.org/download/source/${MYPN}/${MYPN}-${PV}.tgz"
  14
  15 LICENSE="EPL-1.0"
  16 SLOT="0/6"
  17 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  18 IUSE="doc examples static-libs test"
  19
  20 RDEPEND="
  21         sci-libs/coinor-bcp:=
  22         sci-libs/coinor-bonmin:=
  23         sci-libs/coinor-couenne:=
  24         sci-libs/coinor-clp:=
  25         sci-libs/coinor-dylp:=
  26         sci-libs/coinor-symphony:=
  27         sci-libs/coinor-utils:=
  28         sci-libs/coinor-vol:=
  29         sci-libs/ipopt:="
  30 DEPEND="${RDEPEND}
  31         virtual/pkgconfig
  32         doc? ( app-doc/doxygen[dot] )
  33         test? ( sci-libs/coinor-sample )"
  34
  35 S="${WORKDIR}/${MYPN}-${PV}/${MYPN}"
  36
  37 src_prepare() {
  38         append-cppflags -DNDEBUG
  39         # needed for the --with-coin-instdir
  40         dodir /usr
  41         sed -i \
  42                 -e "s:lib/pkgconfig:$(get_libdir)/pkgconfig:g" \
  43                 configure || die
  44         autotools-utils_src_prepare
  45 }
  46
  47 src_configure() {
  48         local myeconfargs=(
  49                 --enable-dependency-linking
  50                 --with-coin-instdir="${ED}"/usr
  51         )
  52         autotools-utils_src_configure
  53 }
  54
  55 src_test() {
  56         autotools-utils_src_test test
  57 }
  58
  59 src_install() {
  60         autotools-utils_src_install
  61         use doc && dodoc doc/*.pdf
  62 }