sci-libs/clblast/clblast-0.10.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit cmake-utils toolchain-funcs
   7
   8 MYPN="CLBlast"
   9
  10 DESCRIPTION="Tuned OpenCL BLAS"
  11 HOMEPAGE="https://github.com/CNugteren/CLBlast"
  12 SRC_URI="https://github.com/CNugteren/${MYPN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="Apache-2.0"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  17 IUSE="client doc examples test"
  18 RESTRICT="!test? ( test )"
  19
  20 RDEPEND="virtual/opencl"
  21 DEPEND="${RDEPEND}
  22         test? (
  23           virtual/cblas
  24           virtual/pkgconfig
  25         )
  26 "
  27 S="${WORKDIR}/${MYPN}-${PV}"
  28
  29 src_prepare() {
  30         # no forced optimisation, libdir
  31         sed -e 's/-O3//g' \
  32                 -e 's/DESTINATION lib/DESTINATION ${CMAKE_INSTALL_LIBDIR}/g' \
  33                 -i CMakeLists.txt || die
  34         cmake-utils_src_prepare
  35 }
  36
  37 src_configure() {
  38         mycmakeargs+=(
  39                 -DBUILD_SHARED_LIBS=ON
  40                 -DSAMPLES=OFF
  41                 -DCLIENTS="$(usex client)"
  42                 -DTESTS="$(usex test)"
  43         )
  44         if use test || use client; then
  45                 mycmakeargs+=(
  46                         -DNETLIB=ON
  47                         -DCBLAS_INCLUDE_DIRS="$($(tc-getPKG_CONFIG) --cflags-only-I cblas| awk '{print $1}' | sed 's/-I//')"
  48                         -DCBLAS_LIBRARIES="$($(tc-getPKG_CONFIG) --libs cblas)"
  49                         -DREF_LIBRARIES="$($(tc-getPKG_CONFIG) --libs cblas)"
  50                 )
  51         fi
  52         cmake-utils_src_configure
  53 }
  54
  55 src_test() {
  56         cmake-utils_src_test alltests
  57 }
  58
  59 src_install() {
  60         cmake-utils_src_install
  61         dodoc README.md CONTRIBUTING.md CHANGELOG
  62         use doc && dodoc -r doc
  63         if use examples; then
  64                 insinto /usr/share/doc/${PF}/examples
  65                 doins -r samples/*
  66                 docompress -x /usr/share/doc/${PF}/examples
  67         fi
  68 }