sci-libs/cgnslib/cgnslib-3.3.0.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 FORTRAN_NEEDED="fortran"
   7 FORTRAN_STANDARD="90 2003"
   8
   9 inherit cmake-utils fortran-2
  10
  11 DESCRIPTION="CFD General Notation System standard library"
  12 HOMEPAGE="http://www.cgns.org/"
  13 SRC_URI="https://github.com/CGNS/CGNS/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  14
  15 LICENSE="ZLIB"
  16 SLOT="0/3"
  17 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  18 IUSE="doc examples fortran hdf5 legacy mpi static-libs szip test tools"
  19
  20 RDEPEND="hdf5? ( sci-libs/hdf5:=[mpi=,szip=] )
  21         tools? (
  22                 dev-lang/tcl:=
  23                 dev-lang/tk:=
  24                 x11-libs/libXmu:=
  25                 virtual/glu
  26                 virtual/opengl
  27         )"
  28 DEPEND="${RDEPEND}"
  29
  30 S="${WORKDIR}/CGNS-${PV}"
  31
  32 pkg_setup() {
  33         use fortran && fortran-2_pkg_setup
  34 }
  35
  36 src_prepare() {
  37         # gentoo libdir
  38         sed -e '/DESTINATION/s|lib)|lib${LIB_SUFFIX})|g' \
  39                 -e 's|lib LIBDIR|lib${LIB_SUFFIX} LIBDIR|' \
  40                 -e 's|/lib"|/lib${LIB_SUFFIX}"|'\
  41                 -i CMakeLists.txt src/CMakeLists.txt || die
  42         # dont hard code link
  43         sed -e '/link_directories/d' \
  44                 -i src/tools/CMakeLists.txt src/cgnstools/*/CMakeLists.txt || die
  45         cmake-utils_src_prepare
  46 }
  47
  48 src_configure() {
  49         local mycmakeargs=(
  50                 -DCGNS_BUILD_SHARED=ON
  51                 -DCGNS_USED_SHARED=ON
  52                 -DCGNS_BUILD_CGNSTOOLS="$(usex tools)"
  53                 -DCGNS_ENABLE_FORTRAN="$(usex fortran)"
  54                 -DCGNS_ENABLE_HDF5="$(usex hdf5)"
  55                 -DCGNS_ENABLE_LEGACY="$(usex legacy)"
  56                 -DCGNS_ENABLE_TESTS="$(usex test)"
  57                 -DHDF5_NEED_MPI="$(usex mpi)"
  58                 -DHDF5_NEED_SZIP="$(usex szip)"
  59                 -DHDF5_NEED_ZLIB="$(usex szip)"
  60         )
  61         cmake-utils_src_configure
  62 }
  63
  64 src_compile() {
  65         # hack to allow parallel building by first producing fortran module
  66         use fortran && cd "${BUILD_DIR}"/src && emake cgns_f.o
  67         cmake-utils_src_compile
  68 }
  69
  70 src_install() {
  71         cmake-utils_src_install
  72         dodoc README.md changelog release_docs/Release.txt
  73         use static-libs || rm "${ED}"/usr/$(get_libdir)/libcgns.a
  74         use doc && dodoc *pdf release_docs/*.pdf
  75         insinto /usr/share/doc/${PF}
  76         use examples && doins -r src/examples
  77 }