sci-libs/cgnslib/cgnslib-3.3.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 FORTRAN_NEEDED="fortran"
   7 FORTRAN_STANDARD="90 2003"
   8
   9 inherit cmake-utils fortran-2
  10
  11 DESCRIPTION="CFD General Notation System standard library"
  12 HOMEPAGE="http://www.cgns.org/"
  13 SRC_URI="https://github.com/CGNS/CGNS/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  14
  15 LICENSE="ZLIB"
  16 SLOT="0/3"
  17 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  18 IUSE="doc examples fortran hdf5 legacy mpi static-libs szip test tools"
  19 RESTRICT="!test? ( test )"
  20
  21 RDEPEND="hdf5? ( sci-libs/hdf5:=[mpi=,szip=] )
  22         tools? (
  23                 dev-lang/tcl:=
  24                 dev-lang/tk:=
  25                 x11-libs/libXmu:=
  26                 virtual/glu
  27                 virtual/opengl
  28         )"
  29 DEPEND="${RDEPEND}"
  30
  31 S="${WORKDIR}/CGNS-${PV}"
  32
  33 pkg_setup() {
  34         use fortran && fortran-2_pkg_setup
  35 }
  36
  37 src_prepare() {
  38         # gentoo libdir
  39         sed -e '/DESTINATION/s|lib)|lib${LIB_SUFFIX})|g' \
  40                 -e 's|lib LIBDIR|lib${LIB_SUFFIX} LIBDIR|' \
  41                 -e 's|/lib"|/lib${LIB_SUFFIX}"|'\
  42                 -i CMakeLists.txt src/CMakeLists.txt || die
  43         # dont hard code link
  44         sed -e '/link_directories/d' \
  45                 -i src/tools/CMakeLists.txt src/cgnstools/*/CMakeLists.txt || die
  46         cmake-utils_src_prepare
  47 }
  48
  49 src_configure() {
  50         local mycmakeargs=(
  51                 -DCGNS_BUILD_SHARED=ON
  52                 -DCGNS_USED_SHARED=ON
  53                 -DCGNS_BUILD_CGNSTOOLS="$(usex tools)"
  54                 -DCGNS_ENABLE_FORTRAN="$(usex fortran)"
  55                 -DCGNS_ENABLE_HDF5="$(usex hdf5)"
  56                 -DCGNS_ENABLE_LEGACY="$(usex legacy)"
  57                 -DCGNS_ENABLE_TESTS="$(usex test)"
  58                 -DHDF5_NEED_MPI="$(usex mpi)"
  59                 -DHDF5_NEED_SZIP="$(usex szip)"
  60                 -DHDF5_NEED_ZLIB="$(usex szip)"
  61         )
  62         cmake-utils_src_configure
  63 }
  64
  65 src_compile() {
  66         # hack to allow parallel building by first producing fortran module
  67         use fortran && cd "${BUILD_DIR}"/src && emake cgns_f.o
  68         cmake-utils_src_compile
  69 }
  70
  71 src_install() {
  72         cmake-utils_src_install
  73         dodoc README.md changelog release_docs/Release.txt
  74         use static-libs || rm "${ED}"/usr/$(get_libdir)/libcgns.a
  75         use doc && dodoc *pdf release_docs/*.pdf
  76         insinto /usr/share/doc/${PF}
  77         use examples && doins -r src/examples
  78 }