sci-geosciences/merkaartor/merkaartor-9999.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PLOCALES="ar cs de en es et fr hr hu id_ID it ja nl pl pt_BR pt ru sk sv uk vi zh_CN zh_TW"
   7
   8 inherit fdo-mime gnome2-utils git-r3 l10n qmake-utils
   9
  10 DESCRIPTION="Qt based map editor for the openstreetmap.org project"
  11 HOMEPAGE="http://www.merkaartor.be https://github.com/openstreetmap/merkaartor"
  12 SRC_URI=""
  13 EGIT_REPO_URI="https://github.com/openstreetmap/merkaartor.git"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS=""
  18 IUSE="debug exif gps libproxy webengine"
  19
  20 RDEPEND="
  21         dev-qt/qtconcurrent:5
  22         dev-qt/qtcore:5
  23         dev-qt/qtgui:5
  24         dev-qt/qtprintsupport:5
  25         dev-qt/qtsingleapplication[X,qt5]
  26         dev-qt/qtsvg:5
  27         dev-qt/qtwidgets:5
  28         dev-qt/qtxml:5
  29         sci-libs/gdal
  30         sci-libs/proj
  31         sys-libs/zlib
  32         exif? ( media-gfx/exiv2:= )
  33         gps? ( >=sci-geosciences/gpsd-3.13[cxx] )
  34         libproxy? ( net-libs/libproxy )
  35         webengine? ( dev-qt/qtwebengine:5 )
  36 "
  37 DEPEND="${RDEPEND}
  38         dev-qt/linguist-tools:5
  39         virtual/pkgconfig
  40 "
  41
  42 DOCS=( AUTHORS CHANGELOG )
  43
  44 src_unpack() {
  45         git-r3_src_unpack
  46 }
  47
  48 src_prepare() {
  49         default
  50
  51         my_rm_loc() {
  52                 sed -i -e "s:../translations/${PN}_${1}.\(ts\|qm\)::" src/src.pro || die
  53                 rm "translations/${PN}_${1}.ts" || die
  54         }
  55
  56         if [[ -n "$(l10n_get_locales)" ]]; then
  57                 l10n_for_each_disabled_locale_do my_rm_loc
  58                 $(qt5_get_bindir)/lrelease src/src.pro || die
  59         fi
  60
  61         # build system expects to be building from git
  62         if [[ ${PV} != *9999 ]] ; then
  63                 sed -i "${S}"/src/Config.pri -e "s:SION = .*:SION = \"${PV}\":g" || die
  64         fi
  65 }
  66
  67 src_configure() {
  68         # TRANSDIR_SYSTEM is for bug #385671
  69         eqmake5 \
  70                 PREFIX="${ED}usr" \
  71                 LIBDIR="${ED}usr/$(get_libdir)" \
  72                 TRANSDIR_MERKAARTOR="${ED}usr/share/${PN}/translations" \
  73                 TRANSDIR_SYSTEM="${EPREFIX}/usr/share/qt5/translations" \
  74                 SYSTEM_QTSA=1 \
  75                 NODEBUG=$(usex debug 0 1) \
  76                 GEOIMAGE=$(usex exif 1 0) \
  77                 GPSDLIB=$(usex gps 1 0) \
  78                 LIBPROXY=$(usex libproxy 1 0) \
  79                 USEWEBENGINE=$(usex webengine 1 0) \
  80                 Merkaartor.pro
  81 }
  82
  83 pkg_preinst() {
  84         gnome2_icon_savelist
  85 }
  86
  87 pkg_postinst() {
  88         fdo-mime_desktop_database_update
  89         gnome2_icon_cache_update
  90 }
  91
  92 pkg_postrm() {
  93         fdo-mime_desktop_database_update
  94         gnome2_icon_cache_update
  95 }