sci-geosciences/bt747/bt747-2.1.7-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 inherit eutils java-pkg-2 java-ant-2
   8
   9 DESCRIPTION="MTK GPS Datalogger Device Control"
  10 HOMEPAGE="http://www.bt747.org"
  11 SRC_URI="mirror://sourceforge/${PN}/Stable/BT747_${PV}_full.zip
  12         http://www.bt747.org/icon/bt747_128x128.gif -> ${PN}.gif"
  13
  14 LICENSE="GPL-3"
  15 SLOT="1"
  16 KEYWORDS="~amd64 ~x86"
  17
  18 CDEPEND="
  19         dev-java/commons-imaging:0
  20         dev-java/jcalendar:1.2
  21         dev-java/jchart2d:0
  22         dev-java/jopt-simple:0
  23         >=dev-java/rxtx-2.2_pre2:2
  24         dev-java/swing-layout:1
  25         dev-java/swingx:1.6
  26         dev-java/swingx-ws:bt747
  27 "
  28
  29 RDEPEND="
  30         ${CDEPEND}
  31         dev-libs/glib:2[dbus]
  32         >=virtual/jre-1.7
  33 "
  34
  35 DEPEND="
  36         ${CDEPEND}
  37         >=virtual/jdk-1.7
  38         app-arch/unzip
  39 "
  40
  41 EANT_BUILD_TARGET="dist.j2se"
  42 EANT_EXTRA_ARGS="-Dskip.proguard=yes -Dsvn=true -Dsvnversion=true -Dbuild.current.revision=Gentoo"
  43 EANT_GENTOO_CLASSPATH="commons-imaging,jcalendar-1.2,jchart2d,jopt-simple-4.4,rxtx-2,swing-layout-1,swingx-1.6,swingx-ws-bt747"
  44 JAVA_ANT_REWRITE_CLASSPATH="yes"
  45
  46 S="${WORKDIR}"
  47
  48 java_prepare() {
  49         # Fix for newer jchart2d.
  50         epatch "${FILESDIR}/jchart2d-3.2.patch"
  51
  52         # Remove all the bundled stuff.
  53         rm -rv dist/ lib/ || die
  54
  55         # GraphicsUtilities moved in later SwingX versions.
  56         sed -i "s:org\.jdesktop\.swingx\.graphics\.GraphicsUtilities:org.jdesktop.swingx.util.GraphicsUtilities:g" \
  57                 src_j2se/net/sf/bt747/j2se/app/list/FileListCellRenderer.java || die
  58
  59         eapply_user
  60 }
  61
  62 src_install() {
  63         dodoc {ChangeLog,README}.txt
  64
  65         java-pkg_dojar dist/*.jar
  66         java-pkg_dolauncher ${PN} --main bt747.j2se_view.BT747Main \
  67                 --java-args="-Xmx192m"
  68
  69         doicon "${DISTDIR}/${PN}.gif"
  70         make_desktop_entry ${PN} BT747 bt747.gif
  71 }