sci-electronics/iverilog/iverilog-0.9.6.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=4
   5
   6 inherit eutils multilib
   7
   8 DESCRIPTION="A Verilog simulation and synthesis tool"
   9 SRC_URI="ftp://icarus.com/pub/eda/verilog/v${PV:0:3}/verilog-${PV}.tar.gz"
  10 HOMEPAGE="http://iverilog.icarus.com/"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ppc sparc x86"
  15 IUSE="examples"
  16
  17 RDEPEND="app-arch/bzip2
  18         sys-libs/readline
  19         sys-libs/zlib"
  20 DEPEND="${RDEPEND}"
  21
  22 S="${WORKDIR}/verilog-${PV}"
  23
  24 src_prepare() {
  25         # Fix tests
  26         mkdir -p lib/ivl
  27         touch lib/ivl/ivl
  28         sed -i -e 's/driver\/iverilog -B./IVERILOG_ROOT="." driver\/iverilog -B./' Makefile.in || die
  29
  30         # Fix LDFLAGS
  31         sed -i -e 's/@shared@/@shared@ $(LDFLAGS)/' {cadpli,tgt-vhdl,tgt-null,tgt-stub,tgt-vvp}/Makefile.in || die
  32 }
  33
  34 src_install() {
  35         emake -j1 \
  36                 prefix="${ED}"/usr \
  37                 mandir="${ED}"/usr/share/man \
  38                 infodir="${ED}"/usr/share/info \
  39                 libdir="${ED}"/usr/$(get_libdir) \
  40                 libdir64="${ED}"/usr/$(get_libdir) \
  41                 vpidir="${ED}"/usr/$(get_libdir)/ivl \
  42                 install
  43
  44         dodoc *.txt
  45         if use examples ; then
  46                 insinto /usr/share/doc/${PF}
  47                 doins -r examples
  48         fi
  49 }