sci-chemistry/viewmol/viewmol-2.4.1-r3.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 )
   7 PYTHON_REQ_USE="tk(-)"
   8
   9 inherit prefix python-single-r1 toolchain-funcs
  10
  11 DESCRIPTION="Open-source graphical front end for computational chemistry programs"
  12 HOMEPAGE="http://viewmol.sourceforge.net/"
  13 SRC_URI="mirror://sourceforge/viewmol/${P}.src.tgz"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE=""
  19 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  20
  21 RDEPEND="
  22         media-libs/libpng:0=
  23         media-libs/tiff:0
  24         virtual/glu
  25         virtual/opengl
  26         x11-libs/libX11
  27         x11-libs/libXi
  28         x11-libs/libXmu
  29         x11-libs/libXt
  30         x11-libs/motif:0
  31         ${PYTHON_DEPS}"
  32 DEPEND="${RDEPEND}
  33         x11-base/xorg-proto"
  34
  35 S="${WORKDIR}/${P}/source"
  36
  37 PATCHES=(
  38         "${FILESDIR}"/${PV}-remove-icc-check.patch
  39         "${FILESDIR}"/${PV}-change-default-paths.patch
  40 )
  41
  42 src_prepare() {
  43         default
  44
  45         eprefixify getrc.c
  46         sed "s:GENTOOLIBDIR:$(get_libdir):g" -i install getrc.c || die
  47         sed "s:GENTOODOCDIR:${PF}:g" -i install || die
  48
  49         mkdir "$(uname -s)" || die
  50         cd "$(uname -s)" || die
  51
  52         cat >> ".config.$(uname -s)" <<- EOF || die
  53                 LIBTIFF = -L"${EPREFIX}/usr/$(get_libdir)"
  54                 TIFFINCLUDE = "${EPREFIX}/usr/include"
  55
  56                 LIBPNG = -L"${EPREFIX}/usr/$(get_libdir)"
  57                 PNGINCLUDE = "${EPREFIX}/usr/include"
  58
  59                 PYTHONVERSION = ${EPYTHON}
  60                 PYTHONINCLUDE = $(python_get_CFLAGS)
  61                 PYTHONLIB = $(python_get_LIBS)
  62
  63                 COMPILER = $(tc-getCC)
  64                 CFLAGS = ${CFLAGS} -DLINUX
  65                 LDFLAGS = ${LDFLAGS}
  66                 SCANDIR=
  67                 INCLUDE=\$(TIFFINCLUDE) -I\$(PNGINCLUDE) \$(PYTHONINCLUDE)
  68                 LIBRARY=\$(LIBTIFF) \$(LIBPNG) \$(PYTHONLIB)
  69                 LIBS=-L"${EPREFIX}/usr/$(get_libdir)" -ltiff -lpng -lz -lGLU -lGL -L"${EPREFIX}/usr/X11R6/lib" -lXm -lXmu -lXp -lXi -lXext -lXt -lX11 -lpthread -lutil -ldl -lm
  70         EOF
  71
  72         cp .config.$(uname -s) makefile || die
  73         cat ../Makefile >> makefile || die
  74 }
  75
  76 src_compile() {
  77         emake -C "$(uname -s)" viewmol_ tm_ bio_ readgamess_ readgauss_ readmopac_ readpdb_
  78         "${EPREFIX}"/bin/bash makeTranslations || die
  79 }
  80
  81 src_install() {
  82         ./install "${ED%/}"/usr || die
  83
  84         # fix broken layout
  85         mv "${ED%/}"/usr/{usr/share,} || die
  86         rm -rf "${ED%/}"/usr/usr || die
  87         mv "${ED%/}"/usr/{$(get_libdir)/${PN}/locale,share} || die
  88         mv "${ED%/}"/usr/{$(get_libdir),libexec} || die
  89 }