sci-chemistry/oasis/oasis-4.0-r3.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils fortran-2 multilib toolchain-funcs
   8
   9 MY_P="${PN}${PV}_Linux"
  10
  11 DESCRIPTION="A direct-method program for SAD/SIR phasing"
  12 HOMEPAGE="http://cryst.iphy.ac.cn/Project/protein/protein-I.html"
  13 SRC_URI="https://dev.gentoo.org/~jlec/distfiles/${MY_P}.zip"
  14
  15 SLOT="0"
  16 KEYWORDS="amd64 ~ppc x86 ~amd64-linux ~x86-linux"
  17 LICENSE="ccp4 oasis"
  18 IUSE="examples +minimal"
  19
  20 RDEPEND="
  21         sci-chemistry/ccp4-apps
  22         sci-chemistry/pymol
  23         sci-libs/mmdb:0
  24         sci-visualization/gnuplot
  25         !minimal? (
  26                 sci-chemistry/solve-resolve-bin
  27                 sci-chemistry/arp-warp-bin
  28         )"
  29 DEPEND="${RDEPEND}
  30         sci-libs/ccp4-libs"
  31
  32 S="${WORKDIR}"/${MY_P}
  33
  34 src_prepare() {
  35         rm bin/{fnp2fp,gnuplot,oasis4-0,seq} || die
  36         epatch "${FILESDIR}"/${PV}-makefile.patch
  37 }
  38
  39 src_compile() {
  40         emake \
  41                 -C src \
  42                 F77="$(tc-getFC)" \
  43                 CFLAGS="${FFLAGS}" \
  44                 CCP4_LIB="${EPREFIX}/usr/$(get_libdir)" \
  45                 Linux
  46 }
  47
  48 src_install() {
  49         exeinto /usr/libexec/ccp4/bin/
  50         doexe src/{${PN},fnp2fp}
  51
  52         exeinto /usr/$(get_libdir)/${PN}
  53         doexe bin/*.*sh
  54
  55         insinto /usr/share/doc/${PF}/html
  56         doins bin/html/*
  57         dosym ../../share/doc/${PF}/html /usr/$(get_libdir)/${PN}/html
  58         chmod 755 "${ED}"/usr/share/doc/${PF}/html/*.{*sh,awk} || die
  59
  60         if use examples; then
  61                 insinto /usr/share/${PN}
  62                 doins -r examples
  63         fi
  64
  65         cat >> "${T}"/25oasis <<- EOF
  66         oasisbin="${EPREFIX}/usr/$(get_libdir)/${PN}"
  67         EOF
  68
  69         doenvd "${T}"/25oasis
  70 }