sci-chemistry/molequeue/molequeue-0.7.1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 PYTHON_COMPAT=( python2_7 )
   8
   9 inherit cmake-utils multilib python-single-r1 versionator virtualx
  10
  11 DESCRIPTION="Abstract, manage and coordinate execution of tasks"
  12 HOMEPAGE="http://www.openchemistry.org/OpenChemistry/project/molequeue.html"
  13 SRC_URI="mirror://sourceforge/project/${PN}/${PN}/${PV}/${P}.tar.gz"
  14
  15 SLOT="0"
  16 LICENSE="BSD"
  17 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  18 IUSE="+client doc server test +zeromq"
  19
  20 REQUIRED_USE="${PYTHON_REQUIRED_USE}
  21         server? ( client )
  22         test? ( server )"
  23
  24 RDEPEND="${PYTHON_DEPS}
  25         dev-qt/qtcore:4
  26         dev-qt/qtgui:4
  27         zeromq? ( net-libs/cppzmq:0= )"
  28 DEPEND="${RDEPEND}
  29         doc? ( app-doc/doxygen )"
  30
  31 src_configure() {
  32         local mycmakeargs=(
  33                 $(cmake-utils_use_enable test TESTING)
  34                 $(cmake-utils_use_use zeromq ZERO_MQ)
  35                 $(cmake-utils_use_build doc DOCUMENTATION)
  36                 $(cmake-utils_use client MoleQueue_BUILD_CLIENT)
  37                 $(cmake-utils_use server MoleQueue_BUILD_APPLICATION)
  38                 -DINSTALL_LIBRARY_DIR=$(get_libdir)
  39                 )
  40         use zeromq && \
  41                 mycmakeargs+=( -DZeroMQ_ROOT_DIR=\"${EPREFIX}/usr\" )
  42
  43         cmake-utils_src_configure
  44 }
  45
  46 src_compile() {
  47         cmake-utils_src_compile all $(usex doc documentation "")
  48 }
  49
  50 src_test() {
  51         VIRTUALX_COMMAND=cmake-utils_src_test
  52         virtualmake
  53 }
  54
  55 src_install() {
  56         use doc && HTML_DOCS=( "${BUILD_DIR}"/docs/html/. )
  57         cmake-utils_src_install
  58 }